I_CacheMaterial

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ICACHEMATERIAL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: {authorizationCheck: #NOT_REQUIRED,
                personalData.blocking: #NOT_REQUIRED
}@EndUserText.label: 'MRP Cache Material'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

@VDM.viewType: #BASIC

@Search.searchable: true
define view I_CacheMaterial
  as select from pph_cache_mat

  association [0..*] to I_MaterialText  as _MaterialText  on $projection.Material = _MaterialText.Material
  association [0..1] to I_MaterialType  as _MaterialType  on $projection.MaterialType = _MaterialType.MaterialType
  association [0..1] to I_MaterialGroup as _MaterialGroup on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
{
  key pph_cache_mat.mandt                                                               as Client,
  key pph_cache_mat.material                                                            as Material,
  key pph_cache_mat.mrparea                                                             as MRPArea,
  key pph_cache_mat.mrpplant                                                            as MRPPlant,
      pph_cache_mat.mrpcontroller                                                       as MRPController,
      cast (pph_cache_mat.materialsafetystockqty as materialsafetystockqty)             as MaterialSafetyStockQty,
      cast (pph_cache_mat.materialreorderpointqty as materialreorderpointqty)           as MaterialReorderPointQty,
      pph_cache_mat.materialbaseunit                                                    as MaterialBaseUnit,
      pph_cache_mat.materialtype                                                        as MaterialType,
      pph_cache_mat.productionsupervisor                                                as ProductionSupervisor,
      pph_cache_mat.factorycalendarid                                                   as FactoryCalendar,

      cast (pph_cache_mat.materialreplnmtleaddurnenddate as mrpleaddurnenddate)         as MaterialReplnmtLeadDurnEndDate,
      cast (pph_cache_mat.totalreplnmtleaddurnenddate as totalreplnmtleaddurnenddate)   as TotalReplnmtLeadDurnEndDate,
      cast (pph_cache_mat.manualplanninghorizonenddate as manualplanninghorizonenddate) as ManualPlanningHorizonEndDate,
      cast (pph_cache_mat.mrpsafetydurationenddate as mrpsafetydurationenddate)         as MRPSafetyDurationEndDate,
      pph_cache_mat.materialprocurementprofile                                          as MaterialProcurementProfile,
      pph_cache_mat.materialprocurementcategory                                         as MaterialProcurementCategory,
      pph_cache_mat.mrptype                                                             as MRPType,
      pph_cache_mat.materialplanneddeliverydurn                                         as MaterialPlannedDeliveryDurn,
      pph_cache_mat.materialplannedproductiondurn                                       as MaterialPlannedProductionDurn,
      pph_cache_mat.mrpsafetyduration                                                   as MRPSafetyDuration,
      pph_cache_mat.planningtimefenceindays                                             as PlanningTimeFenceInDays,
      pph_cache_mat.purchasinggroup                                                     as PurchasingGroup,
      pph_cache_mat.materialgoodsreceiptduration                                        as MaterialGoodsReceiptDuration,
      pph_cache_mat.materialgroup                                                       as MaterialGroup,
      pph_cache_mat.materialabcclassification                                           as MaterialABCClassification,
      pph_cache_mat.mrpgroup                                                            as MRPGroup,
      pph_cache_mat.totalreplenishmentleadduration                                      as TotalReplenishmentLeadDuration,
      pph_cache_mat.lastupdated                                                         as LastBufferUpdateDateTime,

      _MaterialType._Text[1: Language = $session.system_language ].MaterialTypeName     as MaterialTypeName,
      _MaterialGroup._Text[1: Language = $session.system_language ].MaterialGroupName   as MaterialGroupName,
      _MaterialText[ 1: Language = $session.system_language ].MaterialName              as MaterialName,

      _MaterialText,
      _MaterialType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALGROUP",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_MATERIALTYPE",
"I_MATERIALTYPETEXT",
"PPH_CACHE_MAT"
],
"ASSOCIATED":
[
"I_MATERIALGROUP",
"I_MATERIALTEXT",
"I_MATERIALTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/