I_CN_PaytRequisitionPriorityT

@AbapCatalog.sqlViewName: 'ICNREQNPRIT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'PaymentRequisitionPriority'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Payment Requisition Priority - Text'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT,
                                     #CDS_MODELING_DATA_SOURCE, 
                                     #EXTRACTION_DATA_SOURCE, 
                                     #SQL_DATA_SOURCE, 
                                     #SEARCHABLE_ENTITY]
/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ] }*/                                     
define view I_CN_PaytRequisitionPriorityT as select from dd07t
  association to parent I_CN_PaytRequisitionPriorityVH as _Priority
    on $projection.PaymentRequisitionPriority = _Priority.PaymentRequisitionPriority
  association [0..1] to I_Language as _Language 
    on $projection.Language = _Language.Language
{
  @ObjectModel.foreignKey.association: '_Priority'
  @ObjectModel.text.element: ['PaymentRequisitionPriorityName']
  key cast(substring( domvalue_l, 1, 1 ) as payreqn_priority preserving type)   as PaymentRequisitionPriority,

  @Semantics.language: true  
  @ObjectModel.foreignKey.association: '_Language'
  key cast ( ddlanguage as spras preserving type)     as Language,

  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #LOW
  @Semantics.text: true
  cast( ddtext as payreqn_priority_name preserving type )         as PaymentRequisitionPriorityName,
  @Analytics.hidden: true
  @Consumption.hidden: true
  dd07t.domvalue_l as DomainValue,
  
  /* Associations */
  _Language,
  _Priority
}
where dd07t.domname = 'PAYREQN_PRIORITY'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CN_PAYTREQUISITIONPRIORITYVH",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/