I_CFinTemporaryPosting

@EndUserText.label: 'CFIN Temporary Posting'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED

define view entity I_CFinTemporaryPosting
  as select from P_BKPF_COM as Document

{

  key cast( bukrs as fis_bukrs preserving type )                       as CompanyCode,
  key cast( belnr as fins_cfin_tmp_post_belnr preserving type )        as CFinTemporaryPosting,
  key cast( gjahr as fis_gjahr_no_conv preserving type )               as FiscalYear,

      cast( logsystem_sender as fis_logsystem_sender preserving type ) as SenderLogicalSystem,
      cast( bukrs_sender as fis_bukrs_sender preserving type )         as SenderCompanyCode,
      cast( belnr_sender as fis_belnr_sender preserving type)          as SenderAccountingDocument,
      cast( gjahr_sender as fis_gjahr_sender preserving type )         as SenderFiscalYear,

      cast( xreversed as fins_xreversed preserving type )              as IsReversed,
      cast( 'X' as fins_cfin_temp_posting_exists preserving type )     as CFinPndgDocHasTemporaryPosting     

}

where
      reprocessing_status_code =  '4' // Temporary Posting

  and xreversed                <> 'X' // not reversed (assumption: max 1)

  and logsystem_sender         is not initial
  and bukrs_sender             is not initial
  and belnr_sender             is not initial
  and gjahr_sender             is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_BKPF_COM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/