I_CFinBillingDocument

@EndUserText.label: 'CFin Billing Document: Header'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ICFINCIROOT',
  preserveKey: true,
  compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
define view I_CFinBillingDocument
  as select from I_CFinRpldBillingDocument
  //association [1] to target_data_source_name as _association_name on data_source_name.element_name = _association_name.target_element_name

  association [0..*] to I_CFinBillingDocumentItem as _Item      on $projection.SenderLogicalSystem           = _Item.SenderLogicalSystem
                                                               and $projection.CentralFinanceBillingDocument = _Item.CentralFinanceBillingDocument
{

  key   SenderLogicalSystem,
  key   cast( CFinReplicatedBillingDocument as fins_cfin_av_billing_document preserving type ) as CentralFinanceBillingDocument,

        SoldToParty,
        CreationDate,
        CompanyCode,
        SDDocumentCategory,
        CancelledBillingDocument,
        BillingDocumentDate,
        TransactionCurrency,
        AccountingExchangeRate,
        ExchangeRateDate,
        PayerParty,
        AdditionalValueDays,
        SDPricingProcedure,
        PricingDocument,
        TaxDepartureCountry,
        BillingDocumentIsCancelled,
        VATRegistrationOrigin,
        BillingDocumentCategory,

        // association

        _SDDocumentCategory,
        _TransactionCurrency,
        _PayerParty,
        _TaxDepartureCountry,
        _CompanyCode,
        _Item,
        _LogicalSystem,
        _VATRegistrationOrigin,
        _BillingDocumentCategory

}
union all select from I_BillingDocument
association [0..*] to I_CFinBillingDocumentItem as _Item          on  $projection.SenderLogicalSystem           = _Item.SenderLogicalSystem
                                                                  and $projection.CentralFinanceBillingDocument = _Item.CentralFinanceBillingDocument
association [0..1] to I_LogicalSystem           as _LogicalSystem on  $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem
{
      @ObjectModel.foreignKey.association: '_LogicalSystem'
  key cast( '          ' as logsys preserving type  )                          as SenderLogicalSystem,
  key cast( BillingDocument as fins_cfin_av_billing_document preserving type ) as CentralFinanceBillingDocument,

      SoldToParty,
      CreationDate,
      CompanyCode,
      SDDocumentCategory,
      CancelledBillingDocument,
      BillingDocumentDate,
      TransactionCurrency,
      AccountingExchangeRate,
      ExchangeRateDate,
      PayerParty,
      AdditionalValueDays,
      SDPricingProcedure,
      PricingDocument,
      TaxDepartureCountry,
      BillingDocumentIsCancelled,
      VATRegistrationOrigin,
      BillingDocumentCategory,

      // association

      _SDDocumentCategory,
      _TransactionCurrency,
      _PayerParty,
      _TaxDepartureCountry,
      _CompanyCode,
      _Item,
      _LogicalSystem,
      _VATRegistrationOrigin,
      _BillingDocumentCategory
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENT",
"I_CFINRPLDBILLINGDOCUMENT"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENTCATEGORY",
"I_CFINBILLINGDOCUMENTITEM",
"I_COMPANYCODE",
"I_COUNTRY",
"I_CURRENCY",
"I_CUSTOMER",
"I_LOGICALSYSTEM",
"I_SDDOCUMENTCATEGORY",
"I_VATREGISTRATIONORIGIN"
],
"BASE":
[
"I_CFINRPLDBILLINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/