I_CAUploadColumnSeparatorText

@Analytics.technicalName: 'ICAUPLDCOLSEPT'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Upload Trennzeichen für Spalten Texte'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'CAUploadColumnSeparatorValue',
  supportedCapabilities: [
    #CDS_MODELING_ASSOCIATION_TARGET,
    #CDS_MODELING_DATA_SOURCE,
    #LANGUAGE_DEPENDENT_TEXT,
    #SQL_DATA_SOURCE
  ],
  usageType: {
    dataClass: #META,
    serviceQuality: #A,
    sizeCategory: #S
  }
}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define view entity I_CAUploadColumnSeparatorText
  as select from dd07t
  association        to parent I_CAUploadColumnSeparator as _CAUploadColumnSeparator on $projection.CAUploadColumnSeparatorValue = _CAUploadColumnSeparator.CAUploadColumnSeparatorValue
  association [0..1] to I_Language                       as _Language                on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )      as Language,
  
      @ObjectModel.foreignKey.association: '_CAUploadColumnSeparator'
      @ObjectModel.text.element: ['CAUploadColumnSeparatorText']
  key cast( dd07t.domvalue_l as upload_column_separator_kk ) as CAUploadColumnSeparatorValue,
  
      @Consumption.hidden: true
      dd07t.domvalue_l                                       as DomainValue,
      
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      dd07t.ddtext                                           as CAUploadColumnSeparatorText,
      
      _CAUploadColumnSeparator,
      _Language
}
where
      dd07t.domname  = 'UPLOAD_COLUMN_SEPARATOR_KK'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CAUPLOADCOLUMNSEPARATOR",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/