I_CASecurityDepositReqDoc

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@EndUserText.label: 'Security Deposit Request Document'

@VDM.viewType: #COMPOSITE

define view entity I_CASecurityDepositReqDoc
  as select distinct from I_CACashSecurityDepositRequest as RequestDoc
    left outer join       P_CACalculateSecDepReqStatus   as RequestDocStatus on  RequestDoc.CASecurityDeposit = RequestDocStatus.CASecurityDeposit
                                                                             and RequestDoc.CADocumentNumber  = RequestDocStatus.CADocumentNumber
    left outer join       P_CAScrtyDepReqCalculateAmount as RequestAmt       on  RequestDoc.CASecurityDeposit = RequestAmt.CASecurityDeposit
                                                                             and RequestDoc.CADocumentNumber  = RequestAmt.CADocumentNumber
    left outer join       I_CADocumentHeader             as DocHeader        on RequestDoc.CADocumentNumber = DocHeader.CADocumentNumber
  association [1..*] to I_CAScrtyDepDocumentFlow      as _CAScrtyDepDocumentFlow      on  $projection.CASecurityDeposit = _CAScrtyDepDocumentFlow.CASecurityDeposit
                                                                                      and $projection.CADocumentNumber  = _CAScrtyDepDocumentFlow.CADocumentNumber
  association [1..1] to I_CASecurityDepositReqRsnText as _CASecurityDepositReqRsnText on  $projection.CASecurityDepositRequestReason = _CASecurityDepositReqRsnText.CASecurityDepositRequestReason
                                                                                      and _CASecurityDepositReqRsnText.Language      = $session.system_language
  association [1..1] to I_CAScrtyDepDocBPItemStatusT  as _CAScrtyDepDocBPItemStatusT on  $projection.CASecDepDocBPItemStatus        = _CAScrtyDepDocBPItemStatusT.CAScrtyDepDocBPItemStatus
                                                                                      and _CAScrtyDepDocBPItemStatusT.Language      = $session.system_language
  association [1..1] to I_User                        as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association to parent I_CASecurityDepositMgmt       as _CASecurityDepositMgmt       on  $projection.CASecurityDeposit = _CASecurityDepositMgmt.CASecurityDeposit
{
  key RequestDoc.CASecurityDeposit,

  key RequestDoc.CADocumentNumber,
  
      RequestDoc._SecurityDeposit.CAAuthorizationGroup,
      
      RequestDocStatus.CASecDepDocBPItemStatus,

      _CAScrtyDepDocBPItemStatusT.CAScrtyDepDocBPItemStatusText as CASecDepDocBPItemStatusText,

      RequestDoc.CASecurityDepositRequestReason,

      _CASecurityDepositReqRsnText.CASecurityDepositReqReasonText,

      RequestAmt.CAAmountInTransactionCurrency,

      RequestAmt.AmountInRefundCurrency,

      RequestAmt.CAPaymentAmountInPaytCurrency,

      RequestAmt.CAReleasedAmtInPaymentCurrency,

      RequestAmt.CAReversedAmtInTransCurrency,
      
      RequestAmt.CAInterestAmtInPaymentCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast((RequestAmt.CAAmountInTransactionCurrency - RequestAmt.CAReversedAmtInTransCurrency) as request_kk) as CAScrtyDepReqDocRequestAmount,

      RequestAmt.TransactionCurrency,
      
      RequestAmt.PaymentCurrency,
      
      RequestAmt.RefundCurrency,

      DocHeader.CreatedByUser,

      case 
          when _CreatedByUser.UserDescription = ' '
            then DocHeader.CreatedByUser
          when _CreatedByUser.UserDescription <> ' '
            then _CreatedByUser.UserDescription end                                                            as CreatedByUserDescription,

      cast(DocHeader.CreationDate as erdat)                                                                    as CreationDate,

      cast(DocHeader.CreationTime as crtime_kk)                                                                as CreationTime,

      cast ( 
        cast(dats_tims_to_tstmp ( DocHeader.CreationDate,
                                  DocHeader.CreationTime, 
                                  abap_system_timezone( $session.client,  'NULL' ),
                                  $session.client, 
                                  'NULL' ) as cdcreated ) as secdep_creation_time_kk preserving type )         as CAScrtyDepReqDocCreationDteTme, 

      DocHeader.CAPostingDate,

      /* association */      
      _CAScrtyDepDocumentFlow,
      
      _CASecurityDepositReqRsnText,
      
      _CAScrtyDepDocBPItemStatusT as _CASecDepDocBPItemStatusText,
      
      _CreatedByUser,
      
      RequestAmt._TransactionCurrency,
      
      RequestAmt._RefundCurrency,
      
      RequestAmt._PaymentCurrency,
      
      _CASecurityDepositMgmt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CACASHSECURITYDEPOSITREQUEST",
"I_CADOCUMENTHEADER",
"I_CASCRTYDEPDOCBPITEMSTATUST",
"I_CASECURITYDEPOSIT",
"I_CASECURITYDEPOSITREQRSNTEXT",
"I_USER",
"P_CACALCULATESECDEPREQSTATUS",
"P_CASCRTYDEPREQCALCULATEAMOUNT"
],
"ASSOCIATED":
[
"I_CASCRTYDEPDOCBPITEMSTATUST",
"I_CASCRTYDEPDOCUMENTFLOW",
"I_CASECURITYDEPOSITMGMT",
"I_CASECURITYDEPOSITREQRSNTEXT",
"I_CURRENCY",
"I_USER"
],
"BASE":
[
"P_CASCRTYDEPREQCALCULATEAMOUNT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/