I_CAScrtyDepRequestProcess

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@EndUserText.label: 'Document Process of a Specific Request'

@VDM.viewType: #COMPOSITE

define view entity I_CAScrtyDepRequestProcess as
  select from       P_CAScrtyDepReqDocumentAmounts as ScrtyDepReq
    left outer join I_CADocumentHeader   as DocHeader   on ScrtyDepReq.CADocumentNumber = DocHeader.CADocumentNumber
    left outer join I_User               as User        on DocHeader.CreatedByUser      = User.UserID
    association [1..*] to I_CAScrtyDepDocCategoryText   as _CAScrtyDepDocCategoryText  on $projection.CASecurityDepositDocCategory = _CAScrtyDepDocCategoryText.CASecurityDepositDocCategory
  association to parent I_CASecurityDepositReqDocTP as _CASecurityDepositReqDoc on $projection.CASecurityDeposit = _CASecurityDepositReqDoc.CASecurityDeposit
                                                                               and $projection.CASecurityDepositDocument = _CASecurityDepositReqDoc.CADocumentNumber
  association [1] to I_CASecurityDepositMgmtTP as _CASecurityDepositMgmtTP 
    on $projection.CASecurityDeposit = _CASecurityDepositMgmtTP.CASecurityDeposit
{
  key ScrtyDepReq.CASecurityDeposit,

  key ScrtyDepReq.CADocumentNumber,

  key cast(
        case 
          when ScrtyDepReq.CAScrtyDepositClearedDocument = '000000000000'   then '            '
          when ScrtyDepReq.CAScrtyDepositClearedDocument <> '000000000000'  then ScrtyDepReq.CAScrtyDepositClearedDocument
           end as auggb_kk preserving type  )      as CAScrtyDepositClearedDocument,

  key ScrtyDepReq.CASecurityDepositDocument,
      
      ScrtyDepReq._SecurityDeposit.CAAuthorizationGroup,     

      ScrtyDepReq.CASecurityDepositDocCategory,

      ScrtyDepReq.CASecurityDepDocCatCriticality,

      _CAScrtyDepDocCategoryText[1: Language=$session.system_language].CASecurityDepositDocCatText,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( abs(ScrtyDepReq.CAAmountInTransactionCurrency) as secdep_doc_amt_kk preserving type  ) as CAAmountInTransactionCurrency,

      @Semantics.amount.currencyCode: 'PaymentCurrency'
      cast( abs(ScrtyDepReq.CAReleasedAmtInPaymentCurrency) as rel_part_kk preserving type )      as CAReleasedAmtInPaymentCurrency,

      ScrtyDepReq.TransactionCurrency,

      ScrtyDepReq.PaymentCurrency,

      @ObjectModel.text.element: ['CreatedByUserDescription']
      DocHeader.CreatedByUser,

      @Semantics.text:true
      case 
          when User.UserDescription = ' '  then DocHeader.CreatedByUser
          when User.UserDescription <> ' ' then User.UserDescription end as CreatedByUserDescription,

      cast(DocHeader.CreationDate as erdat)                                         as CreationDate,

      cast(DocHeader.CreationTime as crtime_kk)                                     as CreationTime,

      cast (
        cast(dats_tims_to_tstmp ( DocHeader.CreationDate,
                                  DocHeader.CreationTime,
                                  abap_system_timezone( $session.client,  'NULL' ),
                                  $session.client,
                                  'NULL' ) as cdcreated ) as secdep_creation_time_kk preserving type ) as CAScrtyDepReqProcCrtnDteTme,

      /* association */
      ScrtyDepReq._TransactionCurrency,

      ScrtyDepReq._PaymentCurrency,

      _CASecurityDepositMgmtTP,

      _CASecurityDepositReqDoc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CADOCUMENTHEADER",
"I_CASCRTYDEPDOCCATEGORYTEXT",
"I_CASECURITYDEPOSIT",
"I_USER",
"P_CASCRTYDEPREQDOCUMENTAMOUNTS"
],
"ASSOCIATED":
[
"I_CASECURITYDEPOSITMGMTTP",
"I_CASECURITYDEPOSITREQDOCTP",
"I_CURRENCY"
],
"BASE":
[
"P_CASCRTYDEPREQDOCUMENTAMOUNTS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/