I_CAReturnDocumentValueHelp

@AbapCatalog.sqlViewName: 'ICARETURNDOCVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Return Document Wertehilfer'
define view I_CAReturnDocumentValueHelp
  as select from I_CADocumentHeader
  association [1..*] to I_CADocumentType       as _DocType          on $projection.CADocumentType = _DocType.CADocumentType
  association [1..1] to I_CADocumentOriginCode as _DocOriginCode    on $projection.CADocumentOriginCode = _DocOriginCode.CADocumentOriginCode
  association [0..1] to C_CAInvcgUserContact   as _CreatedByContact on $projection.CreatedByUser = _CreatedByContact.ContactCardID
{
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.95, ranking: #HIGH }
  key cast (CADocumentNumber as rlbel_kk preserving type)                                                                                              as CAReturnDocumentNumber,

      @ObjectModel: { text.element:  [ 'CADocumentTypeName' ] }
      CADocumentType,

      @Semantics.text
      _DocType._Text[1:Language = $session.system_language].CADocumentTypeName,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9,  ranking: #MEDIUM }
      CAReconciliationKey,

      CAPostingDate,

      @ObjectModel: { text.element:  [ 'CADocumentOriginCodeName' ] }
      CADocumentOriginCode,

      @Semantics.text
      cast (_DocOriginCode._Text[1: Language=$session.system_language].CADocumentOriginCodeName as htext_gfn_kk)                                       as CADocumentOriginCodeName,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #MEDIUM }
      @ObjectModel: { text.element:  [ 'CreatedByUserName' ] }
      CreatedByUser,

      @Semantics.text
      _CreatedByContact.FullName                                                                                                                       as CreatedByUserName,

      CreationDate,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.94, ranking: #MEDIUM }

      CAReferenceDocument,

      @UI.hidden: true
      CAApplicationArea,

      @UI.hidden: true
      CATaxCompanyCode,


      _DocType,
      _DocOriginCode

}
where
  CADocumentOriginCode = '08' or CADocumentOriginCode = '23'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CAINVCGUSERCONTACT",
"I_CADOCUMENTHEADER",
"I_CADOCUMENTORIGINCODE",
"I_CADOCUMENTORIGINCODETEXT",
"I_CADOCUMENTTYPE",
"I_CADOCUMENTTYPETEXT"
],
"ASSOCIATED":
[
"C_CAINVCGUSERCONTACT",
"I_CADOCUMENTORIGINCODE",
"I_CADOCUMENTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/