I_CANotDisputedOpenItem

@AbapCatalog.sqlViewName: 'INOTDSPUTDOPNITM'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
//@AbapCatalog.preserveKey: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Not Disputed Open Items'
define view I_CANotDisputedOpenItem
  as select from I_CADocumentBPItemPhysical as _Open
  inner join I_CADocumentHeader as _CADocumentHeader on _Open.CADocumentNumber = _CADocumentHeader.CADocumentNumber
{
   key _Open.CADocumentNumber,
   key cast(LTRIM (_Open.CABPItemNumber, '0') as opupk_kk ) as  CABPItemNumber,
   key CARepetitionItemNumber,
   key CASubItemNumber,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       CAAmountInTransactionCurrency,
       @Semantics.currencyCode: true  
       _Open.TransactionCurrency,      
       CAMainTransaction,
       cast(CASubTransaction as tvorg_gfn_kk) as CASubTransaction,
       CANetDueDate, 
       CADeferralDate,
       CAClearingDate,   
       _ClearingReason._Text[1: Language=$session.system_language].CAClearingReasonName,
       CAClearingReason, 
        case when CAClearingDocumentNumber = '' 
             then cast (CAAmountInTransactionCurrency as obetw_gfn_kk ) 
             else cast(0 as obetw_gfn_kk ) end as OpenAmountInTransCrcy,       
       _MainTransaction._Text[1:Language = $session.system_language].CAMainTransactionName,
       _SubTransaction._Text[1:Language = $session.system_language].CASubTransactionName,
       BusinessPartner,
       ContractAccount,
       CAContract,
       CASubApplication,
       CompanyCode,
       cast(_CADocumentHeader.CreationDate as erdat) as CreationDate, 
       cast(_CADocumentHeader.CreationTime as crtime_kk) as CreationTime,       
       _CADocumentHeader.CADocumentOriginCodeName,
       _CADocumentHeader.CreatedByUser,
       _CADocumentHeader.CADocumentOriginCode,
       _CADocumentHeader.DocumentDate,
       _CADocumentHeader.CAPostingDate,
       _CADocumentHeader.CAReferenceDocument,
       _CADocumentHeader._DocType._Text[1:Language = $session.system_language].CADocumentTypeName,
       _CADocumentHeader.CAReconciliationKey,
       _CADocumentHeader.CAReversalDocumentNumber,
       _CADocumentHeader.CAReversedDocumentNumber,   
       _Open.CAApplicationArea,                  
       _BusinessPartner,
       _CAPartner,
       _Currency,
       _DocOriginCode,
       _CompCode,
       _CAHeader,
       _ClearingReason,
       _MainTransaction,
       _DocHeader
}
where _Open.CAClearingReason = '05' or
      _Open.CAClearingReason = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CACLEARINGREASON",
"I_CACLEARINGREASONTEXT",
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTHEADER",
"I_CADOCUMENTTYPE",
"I_CADOCUMENTTYPETEXT",
"I_CAMAINTRANSACTION",
"I_CAMAINTRANSACTIONTEXT",
"I_CASUBTRANSACTION",
"I_CASUBTRANSACTIONTEXT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CACLEARINGREASON",
"I_CADOCUMENTHEADER",
"I_CADOCUMENTORIGINCODE",
"I_CAMAINTRANSACTION",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[
"I_CADOCUMENTBPITEMPHYSICAL",
"I_CADOCUMENTHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/