I_CAInterestNoticeHeader

@EndUserText.label: 'View for Interest Notice Header Data'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'ICAINTRSTNTCHDR'
define view I_CAInterestNoticeHeader 
  with parameters
  @Consumption.hidden: true
  @Environment.systemField: #SYSTEM_LANGUAGE
  P_Language:sylangu
  as select from I_CADocumentHeader as Interest
    join I_CACorrespondenceHeader as Correspndc 
           on  Interest.CADocumentNumber              = Correspndc.Correspondence1stEntityData
           and Correspndc.Correspondence1stEntityIdn  = '0001'
           and (Correspndc.CACorrespondenceType = '0007' or Correspndc.CACorrespondenceType = '0018')
    join P_CAInterestNoticeTotalAmount as Amount
           on Interest.CADocumentNumber               = Amount.CADocumentNumber
           {
    key Correspndc.CACorrespondence,
    key Correspndc.CACorrespondenceType,
        Correspndc.BusinessPartner,
        Correspndc.CAContract,
        Correspndc.ContractAccount,
        Correspndc.CompanyCode,
        Correspndc.Language,
        Correspndc._ContrAcc.ContractAccountName,
        Correspndc.CorrespondenceIssueDate,
        Interest.CADocumentNumber,
        Interest.CAApplicationArea,
        Interest.CADocumentType,
        Interest.CADocumentOriginCode,
        Interest.CreatedByUser,
        Interest.CreationDate,
        Interest.CreationTime,
        Interest.DocumentDate,
        Interest.CAPostingDate,
        Interest.CADocumentClass, 
        Interest.CATaxCompanyCode,
        Interest.CAReversalDocumentNumber,
        Interest.CADocumentVersion,
        Amount.TransactionCurrency,
        @Semantics.amount.currencyCode: 'TransactionCurrency'
        Amount.TotalInterestAmountInTransCrcy  
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CACORRESPONDENCEHEADER",
"I_CADOCUMENTHEADER",
"I_CONTRACTACCOUNTHEADER",
"P_CAINTERESTNOTICETOTALAMOUNT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/