I_CADisputeCaseFllwUpPosting

@AbapCatalog.sqlViewName: 'ICADCFLLWUP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Disputed Follow Up Posting Document'
define view I_CADisputeCaseFllwUpPosting as select from I_CADisputeCaseAmountChange
  left outer join I_CADocumentHeader as _CADocumentHeader on I_CADisputeCaseAmountChange.CADocumentNumber = _CADocumentHeader.CADocumentNumber
  inner join I_CADisputeCase         as _Case             on _Case.CaseUUID = I_CADisputeCaseAmountChange.CaseUUID
  inner join I_CADisputedObject      as _DisputedObject   on I_CADisputeCaseAmountChange.CaseUUID = _DisputedObject.CaseUniqueID
                                                          and I_CADisputeCaseAmountChange.CADocumentNumber = _DisputedObject.CADocumentNumber
{
  key _CADocumentHeader.CADocumentNumber,
  key _DisputedObject.CaseUniqueID,
  key I_CADisputeCaseAmountChange.CADisputedAmountType,
  
  _DisputedObject.ObjectType,
  _DisputedObject.ObjectKey,
  _DisputedObject.RelationshipNumber,
  _DisputedObject.RelationToLinkedObject,
  cast(_CADocumentHeader.CreationDate as erdat preserving type ) as CreationDate,
  cast(_CADocumentHeader.CreationTime as crtime_kk preserving type ) as CreationTime, 
  _CADocumentHeader.CADocumentOriginCodeName,
  CADisputeAmount as CAAmountInTransactionCurrency,
  I_CADisputeCaseAmountChange.TransactionCurrency,
  _CADocumentHeader.CreatedByUser,
  _CADocumentHeader.CADocumentOriginCode,
  cast('' as hvorg_kk ) as CAMainTransaction,
  cast('' as tvorg_gfn_kk ) as CASubTransaction,
  cast('' as hvorg_txt ) as CAMainTransactionName,
  cast('' as tvorg_txt ) as CASubTransactionName,  
  CADisputedAmountTypeName,
  _CADocumentHeader.CAReversalDocumentNumber,
  _CADocumentHeader.CAReversedDocumentNumber,
  _Case.CADisputeType,
  _DisputedObject.BusinessPartner,
  _DisputedObject.ContractAccount
}
 where I_CADisputeCaseAmountChange.CADisputedAmountType = '01'
    or I_CADisputeCaseAmountChange.CADisputedAmountType = '02'
    or I_CADisputeCaseAmountChange.CADisputedAmountType = '03'
    or I_CADisputeCaseAmountChange.CADisputedAmountType = '04'
    or I_CADisputeCaseAmountChange.CADisputedAmountType = '06'
    or I_CADisputeCaseAmountChange.CADisputedAmountType = '07'
    or I_CADisputeCaseAmountChange.CADisputedAmountType = '08'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CADISPUTECASE",
"I_CADISPUTECASEAMOUNTCHANGE",
"I_CADISPUTEDOBJECT",
"I_CADOCUMENTHEADER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/