I_CABillgDocInvcgStatusText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Fakturierungsstatus für Abr.bel. (Text)'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'CABillgDocumentInvcgStatus',
  supportedCapabilities: [
    #CDS_MODELING_ASSOCIATION_TARGET,
    #CDS_MODELING_DATA_SOURCE,
    #LANGUAGE_DEPENDENT_TEXT,
    #SQL_DATA_SOURCE
  ],
  usageType: {
    dataClass: #META,
    serviceQuality: #A,
    sizeCategory: #S
  }
}
@Search.searchable: true
@VDM.viewType: #BASIC

define view entity I_CABillgDocInvcgStatusText
  as select from dd07t
  association        to parent I_CABillgDocInvcgStatus as _CABillgDocInvcgStatus on $projection.CABillgDocumentInvcgStatus = _CABillgDocInvcgStatus.CABillgDocumentInvcgStatus
  association [0..1] to I_Language                     as _Language              on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,

      @ObjectModel.foreignKey.association: '_CABillgDocInvcgStatus'
      @ObjectModel.text.element: ['CABillgDocumentInvcgStatusText']
  key cast( dd07t.domvalue_l as invstatus_kk )          as CABillgDocumentInvcgStatus,

      @Consumption.hidden: true
      dd07t.domvalue_l                                  as DomainValue,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      dd07t.ddtext                                      as CABillgDocumentInvcgStatusText,

      _CABillgDocInvcgStatus,
      _Language
}
where
      dd07t.domname  = 'INVSTATUS_KK'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CABILLGDOCINVCGSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/