I_BusinessPartnerSupplier

@AbapCatalog.sqlViewName: 'IBPSUPPLIER'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'Supplier'
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: 'IsBusinessPurposeCompleted'

@EndUserText.label: 'Business Partner Supplier'
@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
      automatic: true
    }
  }
}
@Metadata.allowExtensions: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm : #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                     #EXTRACTION_DATA_SOURCE]

define view I_BusinessPartnerSupplier
  as select from    I_Supplier as Supplier
    inner join      cvi_vend_link on Supplier.Supplier = cvi_vend_link.vendor
    left outer join but000        on cvi_vend_link.partner_guid = but000.partner_guid

  association [1..1] to I_Supplier_to_BusinessPartner as _SupplierToBusinessPartner on $projection.Supplier = _SupplierToBusinessPartner.Supplier

  association [0..1] to E_Supplier                    as _SupplierExt               on $projection.Supplier = _SupplierExt.Supplier

  association [1..*] to I_SupplierAccountGroupText    as _ReferenceAccountGroupText on $projection.ReferenceAccountGroup = _ReferenceAccountGroupText.SupplierAccountGroup

  association [0..1] to I_Supplier_VH                 as _SupplierAlternativePayee  on $projection.SupplierAlternativePayee = _SupplierAlternativePayee.Supplier

  association [0..1] to I_Supplier_VH                 as _FiscalAddress             on $projection.FiscalAddress = _FiscalAddress.Supplier

  association [1..1] to I_BusinessPartner             as _BusinessPartner           on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

{
  key Supplier.Supplier,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key but000.partner                                  as BusinessPartner,
      cvi_vend_link.partner_guid                      as BusinessPartnerUUID,
      but000.type                                     as BusinessPartnerCategory,
      //--[ GENERATED:012:E6ExH29r7jY4pF7Dkl2TM0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SupplierAccountGroupStdVH',
                     element: 'SupplierAccountGroup' }
        }]
      // ]--GENERATED

      @ObjectModel: {
          foreignKey.association: '_SupplierAccountGroup'
        }
      @ObjectModel.text.association: '_SupplierAccountGroupText'
      Supplier.SupplierAccountGroup,
      Supplier.FormOfAddress,
      Supplier.InternationalLocationNumber1,
      Supplier.InternationalLocationNumber2,
      Supplier.InternationalLocationNumber3,
      @ObjectModel.text.association: '_ReferenceAccountGroupText'
      Supplier.ReferenceAccountGroup,
      @Consumption.valueHelp: '_SupplierAlternativePayee'
      @ObjectModel.foreignKey.association: '_SupplierAlternativePayee'
      Supplier.AlternativePayeeAccountNumber          as SupplierAlternativePayee,
      Supplier.Customer,
      Supplier.PostingIsBlocked,
      Supplier.PurchasingIsBlocked,
      Supplier.VATLiability,
      Supplier.PaymentIsBlockedForSupplier,
      Supplier.SuplrProofOfDelivRlvtCode,
      Supplier.BR_TaxIsSplit,
      cast( 'X' as sdraft_is_active preserving type ) as IsActiveEntity,
      Supplier.AuthorizationGroup,
      Supplier.IsToBeAcceptedAtOrigin,
      Supplier.SupplierCorporateGroup,
      Supplier.ResponsibleType,
      @Consumption.valueHelp: '_FiscalAddress'
      Supplier.FiscalAddress,
      Supplier.SupplierProcurementBlock,
      Supplier.DataExchangeInstructionKey,
      Supplier.BPIsEqualizationTaxSubject,
      Supplier.BRSpcfcTaxBasePercentageCode,
      Supplier.DataMediumExchangeIndicator,
      Supplier.TranspServiceAgentStstcGrp,
      Supplier.TaxNumberResponsible,
      Supplier.TaxNumberType,
      Supplier.SuplrQualityManagementSystem,
      Supplier.SuplrQltyInProcmtCertfnValidTo,
      Supplier.SupplierIsSubRangeRelevant,
      Supplier.TrainStationName,
      Supplier.AlternativePayeeIsAllowed,
      Supplier.PaytSlipWthRefSubscriber,
      Supplier.SupplierIsPlantRelevant,
      Supplier.FactoryCalendar,
      Supplier.SupplierPlant,
      Supplier.DeletionIndicator,
      @Semantics.booleanIndicator: true
      Supplier.IsBusinessPurposeCompleted,
      Supplier.PaymentReason,
      Supplier.SupplierCentralDeletionIsBlock,
      _SupplierToBusinessPartner,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController1,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController2,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController3,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController4,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController6,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController7,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController8,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController9,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      Supplier.DataController10,

      Supplier.IsOneTimeAccount,
      
      _SupplierAccountGroup,
      _SupplierAccountGroupText,
      _ReferenceAccountGroupText,
      _SupplierAlternativePayee,
      _FiscalAddress,
      _ProcurementBlock,
      _QualityManagementSystem,
      _BusinessPartner


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLIER",
"BUT000",
"CVI_VEND_LINK"
],
"ASSOCIATED":
[
"E_SUPPLIER",
"I_BUSINESSPARTNER",
"I_PROCUREMENTBLOCK",
"I_QUALITYMANAGEMENTSYSTEM",
"I_SUPPLIERACCOUNTGROUP",
"I_SUPPLIERACCOUNTGROUPTEXT",
"I_SUPPLIER_TO_BUSINESSPARTNER",
"I_SUPPLIER_VH"
],
"BASE":
[
"I_SUPPLIER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/