I_BusinessPartnerSalesAreaTP

@AbapCatalog.sqlViewName: 'IBUPASALESAREATP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel.writeEnabled: true
@ObjectModel.writeDraftPersistence: 'SALESAREA_D'

@ObjectModel.semanticKey: ['BusinessPartner','SalesOrganization','DistributionChannel','Division']

@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@EndUserText.label: 'Association View For BP Sales Area'

define view I_BusinessPartnerSalesAreaTP

  as select from I_Businesspartnersalesarea as BusinessPartnerSalesArea

  association [0..1] to E_BPSALESAREA_D               as _DraftExtension              on  $projection.SalesOrganization   = _DraftExtension.SalesOrganization
                                                                                      and $projection.DistributionChannel = _DraftExtension.DistributionChannel
                                                                                      and $projection.Division            = _DraftExtension.Division
                                                                                      and $projection.Customer            = _DraftExtension.Customer
  association [0..1] to E_BPSALESAREA_D               as _ActiveExtension             on  $projection.SalesOrganization   = _ActiveExtension.SalesOrganization
                                                                                      and $projection.DistributionChannel = _ActiveExtension.DistributionChannel
                                                                                      and $projection.Division            = _ActiveExtension.Division
                                                                                      and $projection.Customer            = _ActiveExtension.Customer


  association [1..1] to I_BusinessPartnerTP           as _BusinessPartner             on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner



  association [1..*] to I_BusinessPartnerSlsAreaTaxTP as _BusinessPartnerSalesAreaTax on  $projection.BusinessPartner     = _BusinessPartnerSalesAreaTax.BusinessPartner
                                                                                      and $projection.SalesOrganization   = _BusinessPartnerSalesAreaTax.SalesOrganization
                                                                                      and $projection.DistributionChannel = _BusinessPartnerSalesAreaTax.DistributionChannel
                                                                                      and $projection.Division            = _BusinessPartnerSalesAreaTax.Division

  association [1..*] to I_BusinessPartnerPartFuncTP   as _BusinessPartnerPartFunc     on  $projection.BusinessPartner     = _BusinessPartnerPartFunc.BusinessPartner
                                                                                      and $projection.SalesOrganization   = _BusinessPartnerPartFunc.SalesOrganization
                                                                                      and $projection.DistributionChannel = _BusinessPartnerPartFunc.DistributionChannel
                                                                                      and $projection.Division            = _BusinessPartnerPartFunc.Division


  association [1..*] to I_BPSalesAreaTextTP           as _BPSalesAreaText             on  $projection.BusinessPartner     = _BPSalesAreaText.BusinessPartner
                                                                                      and $projection.SalesOrganization   = _BPSalesAreaText.SalesOrganization
                                                                                      and $projection.DistributionChannel = _BPSalesAreaText.DistributionChannel
                                                                                      and $projection.Division            = _BPSalesAreaText.Division

  association [0..1] to I_SalesOrganizationText       as _SalesOrgText                on  $projection.SalesOrganizationForEdit = _SalesOrgText.SalesOrganization
                                                                                      and _SalesOrgText.Language               = $session.system_language

  association [1..*] to I_BPCustSalesAreaAddrDepdntTP as _CustSlsAreaAddrDepdntInfo   on  $projection.BusinessPartner     = _CustSlsAreaAddrDepdntInfo.BusinessPartner
                                                                                      and $projection.SalesOrganization   = _CustSlsAreaAddrDepdntInfo.SalesOrganization
                                                                                      and $projection.DistributionChannel = _CustSlsAreaAddrDepdntInfo.DistributionChannel
                                                                                      and $projection.Division            = _CustSlsAreaAddrDepdntInfo.Division
  
  //association [0..1] to I_TransportationLocation     as _TransportationLocation       on  $projection.IncotermsSupChnDvtgLocAddlUUID = _TransportationLocation.LocationAdditionalUUID


{

  key BusinessPartnerSalesArea.BusinessPartner,

  key BusinessPartnerSalesArea.SalesOrganization,


  key BusinessPartnerSalesArea.DistributionChannel,


  key BusinessPartnerSalesArea.Division,

      BusinessPartnerSalesArea.BusinessPartner                  as BusinessPartnerForEdit,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SalesOrganization                as SalesOrganizationForEdit,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.DistributionChannel              as DistributionChannelForEdit,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.Division                         as DivisionForEdit,
      BusinessPartnerSalesArea.BusinessPartnerUUID,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.Customer,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustomerGroup,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SalesOffice,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SalesGroup,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.AccountByCustomer,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustomerABCClassification,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.Currency,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustomerPriceGroup,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustomerPricingProcedure,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      case
         when BusinessPartnerSalesArea.DeliveryPriority = '00' then ''
         else BusinessPartnerSalesArea.DeliveryPriority
      end                                                       as DeliveryPriority,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.OrderCombinationIsAllowed,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.ShippingCondition,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SupplyingPlant,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.DeliveryIsBlockedForCustomer,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.BillingIsBlockedForCustomer,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CompleteDeliveryIsDefined,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.PartialDeliveryIsAllowed,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.InvoiceDate,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.IncotermsClassification,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.IncotermsTransferLocation,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.IncotermsVersion,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.IncotermsLocation1,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.IncotermsLocation2,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustomerPaymentTerms,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustomerAccountAssignmentGroup,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.OrderIsBlockedForCustomer,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.PriceListType,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SalesDistrict,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.PaymentGuaranteeProcedure,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.InvoiceListSchedule,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.ExchangeRateType,
      BusinessPartnerSalesArea.AuthorizationGroup,

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.ItemOrderProbabilityInPercent,
      BusinessPartnerSalesArea.AdditionalCustomerGroup1,
      BusinessPartnerSalesArea.AdditionalCustomerGroup2,
      BusinessPartnerSalesArea.AdditionalCustomerGroup3,
      BusinessPartnerSalesArea.AdditionalCustomerGroup4,
      BusinessPartnerSalesArea.AdditionalCustomerGroup5,

      BusinessPartnerSalesArea.CustomerStatisticsGroup,

      BusinessPartnerSalesArea.UnderdelivTolrtdLmtRatioInPct,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.OverdelivTolrtdLmtRatioInPct,
      BusinessPartnerSalesArea.MaxNmbrOfPartialDelivery,
      BusinessPartnerSalesArea.SuplrIsRlvtForSettlmtMgmt,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.ProductUnitGroup,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SlsDocIsRlvtForProofOfDeliv,
      BusinessPartnerSalesArea.SlsUnlmtdOvrdelivIsAllwd,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CreditControlArea,
      BusinessPartnerSalesArea.CustomerIsRebateRelevant,
      BusinessPartnerSalesArea.InspSbstHasNoTimeOrQuantity,
      BusinessPartnerSalesArea.ManualInvoiceMaintIsRelevant,
      
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ProofOfDeliveryTimeValue'
      BusinessPartnerSalesArea.ProofOfDeliveryTime,
      BusinessPartnerSalesArea.ProofOfDeliveryTimeValue,
      

      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.SalesItemProposal,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea.CustProdProposalProcedure,
      //BusinessPartnerSalesArea.SalesIsBlockedForCustomer,

      //BusinessPartnerSalesArea.IncotermsLocation1Identifier ,

      BusinessPartnerSalesArea.IncotermsSupChnLoc2AddlUUID,
      BusinessPartnerSalesArea.IncotermsSupChnLoc1AddlUUID,
      BusinessPartnerSalesArea.IncotermsSupChnDvtgLocAddlUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea._IncotermsSupChnLoc1.Location    as IncotermsLocation1Identifier,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea._IncotermsSupChnLoc2.Location    as IncotermsLocation2Identifier,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerSalesArea._IncotermsSupChnDvtgLoc.Location as IncotermsDvtgLocIdentifier,
      _SalesOrgText.SalesOrganizationName,
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BusinessPartnerSalesAreaTax,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BusinessPartnerPartFunc,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CustSlsAreaAddrDepdntInfo,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPSalesAreaText,

      _SalesOrgText,
      _DelivBlkRsnValueHelp,
      _DeliveryBlockReasonText,
      _BillingBlockReasonValueHelp,
      _BillingBlockReasonText,
      _SalesDistrictValueHelp,
      _SalesDistrictText,
      _CustomerGroupValueHelp,
      _ShippingConditionValueHelp,
      _ShippingConditionText,
      _AccountAssgmtGroupValueHelp,
      _CustAccountAssgmtGroupText,
      _CustomerPriceGroupValueHelp,
      _CustomerPriceGroupText,
      _CustomerGroupText,
      _FactoryCalendar,
      _ExchangeRateType,
      _PaytGuarProcedVH

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERSALESAREA",
"I_SALESORGANIZATIONTEXT",
"I_TRANSPORTATIONLOCATION"
],
"ASSOCIATED":
[
"E_BPSALESAREA_D",
"I_BILLINGBLOCKREASON",
"I_BILLINGBLOCKREASONTEXT",
"I_BPCUSTSALESAREAADDRDEPDNTTP",
"I_BPSALESAREATEXTTP",
"I_BUSINESSPARTNERPARTFUNCTP",
"I_BUSINESSPARTNERSLSAREATAXTP",
"I_BUSINESSPARTNERTP",
"I_CUSTOMERACCOUNTASSGMTGROUP",
"I_CUSTOMERACCOUNTASSGMTGROUPT",
"I_CUSTOMERGROUP",
"I_CUSTOMERGROUPTEXT",
"I_CUSTOMERPAYTGUARPROCED",
"I_CUSTOMERPRICEGROUP",
"I_CUSTOMERPRICEGROUPTEXT",
"I_DELIVERYBLOCKREASON",
"I_DELIVERYBLOCKREASONTEXT",
"I_EXCHANGERATETYPE",
"I_FACTORYCALENDAR",
"I_SALESDISTRICT",
"I_SALESDISTRICTTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SHIPPINGCONDITION",
"I_SHIPPINGCONDITIONTEXT"
],
"BASE":
[
"I_BUSINESSPARTNERSALESAREA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/