I_BusinessPartnerRoleTP_2

//@AbapCatalog.sqlViewName: 'IBUPAROLETP2'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Role'
//@ClientHandling.algorithm : #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

define view entity I_BusinessPartnerRoleTP_2
  as select from I_BusinessPartner_to_BP_Role as BusinessPartnerRole
  association        to parent I_BusinessPartnerTP_2 as _BusinessPartner       on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  //                                                                               and $projection.BPDrftUUID = _BusinessPartner.bpdrftuuid

  association [0..1] to I_BusinessPartnerRole        as _BusinessPartnerRoleVH on $projection.BusinessPartnerRole = _BusinessPartnerRoleVH.BusinessPartnerRole
{
      //  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPDrftUUID,

      //  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPRoleDrftUUID,

  key BusinessPartner,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.foreignKey.association: '_BusinessPartnerRoleVH'
  key BusinessPartnerRole,

      BusinessPartnerRole.BusinessPartnerRole         as BusinessPartnerRoleForEdit,
      @Semantics.businessDate.from: true
      case when ValidFrom != 00010101000000
      then tstmp_to_dats(BusinessPartnerRole.ValidFrom,'UTC',  $session.client, 'NULL')
      else cast ( '00010103' as abap.dats )
      end                                             as ValidFrom,
      @Semantics.businessDate.to: true
      case when ValidTo != 00010101000000
      then tstmp_to_dats(BusinessPartnerRole.ValidTo,'UTC',  $session.client, 'NULL')
      else cast ( '99991231' as abap.dats)
      end                                             as ValidTo,
      cast( 'X' as sdraft_is_active preserving type ) as BPHasActiveEntity,
      _BusinessPartner.AuthorizationGroup,
      _BusinessPartner.IsBusinessPurposeCompleted,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataControllerSet              as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController1                as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController2                as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController3                as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController4                as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController5                as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController6                as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController7                as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController8                as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController9                as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController10               as DataController10,
      /* Associations */
      _BusinessPartner,
      _BusinessPartner._AuthorizationGroup,
      _BusinessPartnerRoleVH
      //    _BPDataControllerUsage

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERTP_2",
"I_BUSINESSPARTNER_TO_BP_ROLE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERROLE",
"I_BUSINESSPARTNERTP_2",
"I_BUSPARTAUTHORIZATIONGROUP"
],
"BASE":
[
"I_BUSINESSPARTNERTP_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/