I_BusinessPartnerRoleProcTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner Role (Process Data)'

@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view entity I_BusinessPartnerRoleProcTP
  as select from I_BusinessPartnerRoleProc as BusinessPartnerRole
  association        to parent I_BusinessPartnerProcessTP as _BusinessPartner       on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_BusinessPartnerRole             as _BusinessPartnerRoleVH on  $projection.BusinessPartnerRole = _BusinessPartnerRoleVH.BusinessPartnerRole
  association [0..1] to I_BPProcessKPIRecordType          as _RecordType            on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH         as _KPIUpdateStatusText   on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages         as _RecordMessages        on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
      @Search.defaultSearchElement: true
      @Consumption.valueHelp: '_BusinessPartnerRoleVH'
  key BusinessPartnerRole,
      BusinessPartner,
      ValidFrom,
      ValidTo,
      @Semantics.businessDate.from: true
      case when ValidFrom != 00010101000000
      then tstmp_to_dats(ValidFrom,'UTC',  $session.client, 'NULL')
      else cast ( '00010103' as abap.dats )
      end                                                            as ValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidTo != 00010101000000
      then tstmp_to_dats(ValidTo,'UTC',  $session.client, 'NULL')
      else cast ( '99991231' as abap.dats)
      end                                                            as ValidityEndDate,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,
      MDChgProcSrceLastChgdDateTime,
      
      /* Associations */
      _BusinessPartner,
      _BusinessPartnerRoleVH,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERROLEPROC"
],
"ASSOCIATED":
[
"I_BPPROCESSKPIRECORDTYPE",
"I_BUSINESSPARTNERPROCESSTP",
"I_BUSINESSPARTNERROLE",
"I_MDCHANGEPROCESSKPIROWVH",
"I_MDCHGPROCRECORDMESSAGES"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/