I_BusinessPartnerBankGov

@AbapCatalog.sqlViewName: 'IBPBANKGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm : #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Business Partner Bank (Governance)'
define view I_BusinessPartnerBankGov
  as select from I_BusinessPartnerBankProc
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartner         on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
{
      //I_BusinessPartnerBankProc

  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key BankIdentification,
      BusinessPartner,
      BankCountryKey,
      BankNumber,
      BankAccount,
      BankControlKey,
      BankAccountReferenceText,
      BankAccountHolderName,
      BusinessPartnerExternalBankID,
      CollectionAuthInd,
      BankAccountName,
      BPBankDetailsChangeTargetID,
      BPBankIsProtected,
      ValidityStartDateTime,
      ValidityEndDateTime,
      BPBankDetailsChangeDate,
      IBAN,
      _Bank.CityName                      as CityName,
      _BusinessPartner.AuthorizationGroup as AuthorizationGroup,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      )                                   as MasterDataIsCurrent,
      /* Associations */
      //I_BusinessPartnerBankProc

      _BusinessPartner,
      _Bank,
      _IBAN
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_BusinessPartnerBank_2
association [1..1] to I_BusinessPartnerGov as _BusinessPartner on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                               and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                               and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                               and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key BankIdentification,
      BusinessPartner,
      BankCountryKey,
      BankNumber,
      BankAccount,
      BankControlKey,
      BankAccountReferenceText,
      BankAccountHolderName,
      BusinessPartnerExternalBankID,
      CollectionAuthInd,
      BankAccountName,
      BPBankDetailsChangeTargetID,
      BPBankIsProtected,
      ValidityStartDate                           as ValidityStartDateTime,
      ValidityEndDate                             as ValidityEndDateTime,
      BPBankDetailsChangeDate,
      IBAN,
      CityName,
      AuthorizationGroup,
      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,
      /* Associations */
      //I_BusinessPartnerBank

      _BusinessPartner,
      _Bank,
      _IBAN
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANKFORBUSINESSPARTNER",
"I_BUSINESSPARTNERBANKPROC",
"I_BUSINESSPARTNERBANK_2",
"I_BUSINESSPARTNERGOV",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BANKFORBUSINESSPARTNER",
"I_BUSINESSPARTNERGOV",
"I_BUSINESSPARTNERIBAN",
"I_MASTERDATACHANGEPROCESS"
],
"BASE":
[
"I_BUSINESSPARTNERBANKPROC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/