I_BusinessPartnerAddress

@AbapCatalog.sqlViewName: 'IBPADDRESS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_Address' ]
@VDM.viewType: #BASIC
@EndUserText.label: 'Core view for Business Partner Address'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

define view I_BusinessPartnerAddress
  as select from but020 as BusinessPartnerAddress

  association [1..1] to I_Address            as _Address            on  $projection.AddressNumber = _Address.AddressID

  association [1..1] to I_BusinessPartner    as _BusinessPartner    on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                    and $projection.AddressNumber   = _BPProtectedAddress.AddressID
                                   
{
  key BusinessPartnerAddress.partner                                 as BusinessPartner,
  key BusinessPartnerAddress.addrnumber                              as AddressNumber,

      BusinessPartnerAddress.addr_valid_from                         as ValidityStartDate,
      BusinessPartnerAddress.addr_valid_to                           as ValidityEndDate,
      BusinessPartnerAddress.address_guid                            as BusinessPartnerAddressUUID,
      BusinessPartnerAddress.move_addr                               as BPTargetAddressID,
      BusinessPartnerAddress.addr_move_date                          as BPAddressMoveDateTime,
      _Address.CareOfName,
      _Address.FormOfAddress,
      _Address.FullName,
      _Address.HouseNumber,
      _Address.StreetName,
      _Address.HouseNumberSupplementText,
      _Address.District,
      _Address.PostalCode,
      _Address.CityName,
      _Address.Country,
      _Address.Region,
      _Address.AddressTimeZone,
      _Address.TaxJurisdiction,
      _Address.TransportZone,
      _Address.CompanyPostalCode,
      _Address.DeliveryServiceNumber,
      _Address.POBox,
      _Address.POBoxIsWithoutNumber,
      _Address.POBoxPostalCode,
      _Address.POBoxLobbyName,
      _Address.POBoxDeviatingCityName,
      _Address.POBoxDeviatingRegion,
      _Address.POBoxDeviatingCountry,
      _Address.CorrespondenceLanguage,
      _Address.PrfrdCommMediumType,
      _Address.StreetPrefixName,
      _Address.AdditionalStreetPrefixName,
      _Address.StreetSuffixName,
      _Address.AdditionalStreetSuffixName,
      _Address.HomeCityName,
      _Address.DeliveryServiceTypeCode,
      _Address.AddressStreetUnusable, 
      _Address.AddressPostBoxUnusable,
      _Address.Building,
      _Address.Floor,
      _Address.RoomNumber,
      _Address.County,
      _Address.CountyCode,
      _Address.TownshipCode, 
      _Address.TownshipName,
      _Address.CityFileTestStatus,  

      coalesce(_Address._DefaultCorporatePhoneNumber.PhoneNumber, _Address._DefaultPrivatePhoneNumber.PhoneNumber) as PhoneNumber, 
      coalesce(_Address._DefaultCorporatePhoneNumber.DestinationLocationCountry, _Address._DefaultPrivatePhoneNumber.DestinationLocationCountry) as PhoneNumberCountry,   
      coalesce(_Address._DefaultCorporatePhoneNumber.PhoneNumberExtension, _Address._DefaultPrivatePhoneNumber.PhoneNumberExtension) as PhoneNumberExtension,
      coalesce(_Address._DefaultCorpFaxNumber.FaxNumber, _Address._DefaultPrivateFaxNumber.FaxNumber) as FaxNumber,
      coalesce(_Address._DefaultCorpFaxNumber.FaxCountry, _Address._DefaultPrivateFaxNumber.FaxCountry) as FaxCountry,
      coalesce(_Address._DefaultCorpFaxNumber.FaxNumberExtension, _Address._DefaultPrivateFaxNumber.FaxNumberExtension) as FaxNumberExtension,
      coalesce(_Address._DefaultCorpMobilePhoneNumber.PhoneNumber, _Address._DefaultPvtMobilePhoneNumber.PhoneNumber) as MobilePhoneNumber,
      coalesce(_Address._DefaultCorpMobilePhoneNumber.DestinationLocationCountry, _Address._DefaultPvtMobilePhoneNumber.DestinationLocationCountry) as MobilePhoneCountry,
      coalesce(_Address._DefaultCorpEmailAddress.EmailAddress, _Address._DefaultPvtEmailAddress.EmailAddress) as EmailAddress,
      coalesce(_Address._DefaultCorpURLAddress.URLFieldLength, _Address._DefaultPvtURLAddress.URLFieldLength) as URLFieldLength,
      _Address._DefaultURLAddress.WebsiteURL,

      _Address,
      _BusinessPartner,
      _BPProtectedAddress
     
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_ADDRESSFAXNUMBER",
"I_ADDRESSHOMEPAGEURL",
"I_ADDRESSPHONENUMBER",
"BUT020"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_BPPROTECTEDADDRESS",
"I_BUSINESSPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/