I_BusPartTelephoneNumberTP_2

//@AbapCatalog.sqlViewName: 'IBUPATELTP2'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
//@ClientHandling.algorithm : #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Transactional View for I_BusPartTelephoneNumber'
define view entity I_BusPartTelephoneNumberTP_2
  as select from I_BPTelephoneNumber as BusinessPartnerTelephoneNumber
  association        to parent I_BusinessPartnerAddressTP_2 as _BusinessPartnerAddress on  $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
                                                                                       and $projection.AddressNumber   = _BusinessPartnerAddress.AddressNumber
//                                                                                       and $projection.BPDrftUUID      = _BusinessPartnerAddress.BPDrftUUID

//                                                                                       and $projection.BPAddressDrftUUID = _BusinessPartnerAddress.BPAddressDrftUUID

  association [1..1] to I_BusinessPartnerTP_2               as _BusinessPartner        on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
//                                                                                       and $projection.BPDrftUUID      = _BusinessPartner.BPDrftUUID

  association [0..1] to I_BusPartTelCountryPrefix           as _TelCountryPrefix       on  $projection.DestinationLocationCountry = _TelCountryPrefix.Country
{ 
//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPDrftUUID,

//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPAddressDrftUUID,

//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPTelNmbrDrftUUID,

  key BusinessPartner,
  key AddressID                                                     as AddressNumber,
  key Person,
  key OrdinalNumber,
      @ObjectModel.editableFieldFor: 'OrdinalNumber'
      OrdinalNumber as OrdinalNumberForEdit,
      DestinationLocationCountry,
      _TelCountryPrefix.TelephoneCountryPrefix                      as TelephoneCountryPrefix,
      IsDefaultPhoneNumber,
//      CommNumberIsNotUsed,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      PhoneNumber,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      PhoneNumberExtension,
      InternationalPhoneNumber,
//      PhoneIsSMSEnabled,

      PhoneNumberType,
      ValidityStartDateTime,
      ValidityEndDateTime,
      @Semantics.businessDate.from: true
      case when ValidityStartDateTime != ''
      then cast ( (substring(ValidityStartDateTime,1,8) ) as abap.dats )
      else cast ( '00010101' as abap.dats )
      end                                                           as ValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDateTime != ''
      then cast ( (substring(ValidityEndDateTime,1,8) ) as abap.dats )
      else cast ( '99991231' as abap.dats )
      end                                                           as ValidityEndDate,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataControllerSet              as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController1                as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController2                as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController3                as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController4                as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController5                as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController6                as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController7                as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController8                as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController9                as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController10               as DataController10,
      /* Associations */
      _BusinessPartner,
      _BusinessPartnerAddress,
      _TelCountryPrefix,
      
      _BusinessPartner.AuthorizationGroup,
      _BusinessPartner.IsBusinessPurposeCompleted,
      
      _PhoneNumberCountry,
      _PhoneNumberType,
      _BusinessPartner._AuthorizationGroup as _AuthorizationGroup
      //-- Data controller association        

      //_BPDataControllerUsage

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPTELEPHONENUMBER",
"I_BUSINESSPARTNERTP_2",
"I_BUSPARTTELCOUNTRYPREFIX"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERADDRESSTP_2",
"I_BUSINESSPARTNERTP_2",
"I_BUSPARTAUTHORIZATIONGROUP",
"I_BUSPARTTELCOUNTRYPREFIX",
"I_COUNTRY",
"I_PHONENUMBERTYPE"
],
"BASE":
[
"I_BPTELEPHONENUMBER",
"I_BUSINESSPARTNERTP_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/