I_BusPartScriptedOrgAddress

@AbapCatalog.sqlViewName: 'IBPSCRPTORGADDR'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_ScriptedAddress']//, '_BPDataControllerUsage']

@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'International version of a business partner address'
define view I_BusPartScriptedOrgAddress
  as select from but020                        as BusinessPartnerAddress
    inner join   I_ScriptedOrganizationAddress as ScriptedAddress on BusinessPartnerAddress.addrnumber = ScriptedAddress.AddressNumber
  association [1..1] to I_ScriptedOrganizationAddress as _ScriptedAddress    on  BusinessPartnerAddress.addrnumber     = _ScriptedAddress.AddressNumber
                                                                             and $projection.AddressRepresentationCode = _ScriptedAddress.AddressRepresentationCode
  association [1..1] to I_BusinessPartner             as _BusinessPartner    on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_BPProtectedAddress          as _BPProtectedAddress on  $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                             and $projection.AddressNumber   = _BPProtectedAddress.AddressID
  // association [0..*] to I_BPDataControllerUsage as _BPDataControllerUsage on  $projection.BusinessPartner = _BPDataControllerUsage.BusinessPartner

{
  key BusinessPartnerAddress.partner                  as BusinessPartner,
  key BusinessPartnerAddress.addrnumber               as AddressNumber,
  key ScriptedAddress.AddressRepresentationCode       as AddressRepresentationCode,
      BusinessPartnerAddress.addr_valid_from          as ValidityStartDateTime,
      BusinessPartnerAddress.addr_valid_to            as ValidityEndDateTime,
      bintohex( BusinessPartnerAddress.address_guid ) as BusinessPartnerAddressUUID,

      //ScriptedAddress.AddressNumber,

      ScriptedAddress.CareOfName,
      ScriptedAddress.AdditionalStreetSuffixName,
      ScriptedAddress.CorrespondenceLanguage,
      ScriptedAddress.PrfrdCommMediumType,
      ScriptedAddress.POBox,
      ScriptedAddress.POBoxIsWithoutNumber,
      ScriptedAddress.POBoxPostalCode,
      ScriptedAddress.POBoxLobbyName,
      ScriptedAddress.POBoxDeviatingCityName,
      ScriptedAddress.POBoxDeviatingRegion,
      ScriptedAddress.POBoxDeviatingCountry,
      ScriptedAddress.DeliveryServiceTypeCode,
      ScriptedAddress.DeliveryServiceNumber,
      ScriptedAddress.AddressTimeZone,
      ScriptedAddress.CityFileTestStatus,
      ScriptedAddress.AddressNonDeliverableReason,
      ScriptedAddress.PostBoxNonDeliverableReason,
      ScriptedAddress.FullName,
      ScriptedAddress.CityName,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'DistrictName'
      ScriptedAddress.District,
      ScriptedAddress.District                        as DistrictName,
      ScriptedAddress.HomeCityName,
      ScriptedAddress.PostalCode,
      ScriptedAddress.CompanyPostalCode,
      ScriptedAddress.StreetName,
      ScriptedAddress.StreetPrefixName,
      ScriptedAddress.AdditionalStreetPrefixName,
      ScriptedAddress.StreetSuffixName,
      ScriptedAddress.HouseNumber,
      ScriptedAddress.HouseNumberSupplementText,
      ScriptedAddress.Building,
      ScriptedAddress.Floor,
      ScriptedAddress.RoomNumber,
      ScriptedAddress.Country,
      ScriptedAddress.Region,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BPCountyText'
      ScriptedAddress.County,
      ScriptedAddress.County                          as BPCountyText,
      ScriptedAddress.BusinessPartnerName1,
      ScriptedAddress.BusinessPartnerName2,
      ScriptedAddress.BusinessPartnerName3,
      ScriptedAddress.BusinessPartnerName4,
      ScriptedAddress.TaxJurisdiction,
      ScriptedAddress.TransportZone,
      ScriptedAddress.FormOfAddress,
      ScriptedAddress.SearchTerm1,
      ScriptedAddress.SearchTerm2,

      _BusinessPartner,
      _ScriptedAddress,
      _BPProtectedAddress
      //      _BPDataControllerUsage

}
where
  _BusinessPartner.BusinessPartnerCategory = '2'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_SCRIPTEDORGANIZATIONADDRESS",
"BUT020"
],
"ASSOCIATED":
[
"I_BPPROTECTEDADDRESS",
"I_BUSINESSPARTNER",
"I_SCRIPTEDORGANIZATIONADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/