I_BusPartScriptedGrpAddrGov

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bus Part Grp Addr Vers Gov TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity I_BusPartScriptedGrpAddrGov
  as select from I_BusPartScriptedGrpAddrProc
  association [1..1] to I_BusinessPartnerGov          as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
  association [0..1] to I_BusPartProtectedAddressProc as _BPProtectedAddress      on  $projection.MasterDataChangeProcess = _BPProtectedAddress.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _BPProtectedAddress.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _BPProtectedAddress.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _BPProtectedAddress.MDChgProcessSrceObject
  association [0..1] to I_MasterDataChangeProcess     as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key AddressRepresentationCode,
      BusinessPartner,
      ValidityStartDate,
      ValidityEndDate,
      BusinessPartnerAddressUUID,
      CareOfName,
      AdditionalStreetSuffixName,
      CorrespondenceLanguage,
      PrfrdCommMediumType,
      POBox,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      POBoxLobbyName,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      AddressTimeZone,
      CityFileTestStatus,
      FullName,
      CityName,
      DistrictName,
      HomeCityName,
      PostalCode,
      CompanyPostalCode,
      StreetName,
      StreetPrefixName,
      AdditionalStreetPrefixName,
      StreetSuffixName,
      HouseNumber,
      HouseNumberSupplementText,
      Building,
      Floor,
      RoomNumber,
      Country,
      Region,
      BPCountyText,
      BusinessPartnerName1,
      BusinessPartnerName2,
      TaxJurisdiction,
      TransportZone,
      FormOfAddress,
      SearchTerm1,
      SearchTerm2,

      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      /* Associations */
      _BPProtectedAddress,
      _BusinessPartnerGov
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_BusPartScriptedGroupAddress
association [1..1] to I_BusinessPartnerGov          as _BusinessPartnerGov on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                           and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                           and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                           and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
association [0..1] to I_BusPartProtectedAddressProc as _BPProtectedAddress on  $projection.MasterDataChangeProcess = _BPProtectedAddress.MasterDataChangeProcess
                                                                           and $projection.MDChgProcessStep        = _BPProtectedAddress.MDChgProcessStep
                                                                           and $projection.MDChgProcessSrceSystem  = _BPProtectedAddress.MDChgProcessSrceSystem
                                                                           and $projection.MDChgProcessSrceObject  = _BPProtectedAddress.MDChgProcessSrceObject
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key AddressNumber,
  key AddressRepresentationCode,
      BusinessPartner,
      ValidityStartDateTime                       as ValidityStartDate,
      ValidityEndDateTime                         as ValidityEndDate,
      hextobin(BusinessPartnerAddressUUID)        as BusinessPartnerAddressUUID,
      CareOfName,
      AdditionalStreetSuffixName,
      CorrespondenceLanguage,
      PrfrdCommMediumType,
      POBox,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      POBoxLobbyName,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      AddressTimeZone,
      _ScriptedAddress.CityFileTestStatus,
      FullName,
      CityName,
      DistrictName,
      HomeCityName,
      PostalCode,
      CompanyPostalCode,
      StreetName,
      StreetPrefixName,
      AdditionalStreetPrefixName,
      StreetSuffixName,
      HouseNumber,
      HouseNumberSupplementText,
      Building,
      Floor,
      RoomNumber,
      Country,
      Region,
      BPCountyText,
      BusinessPartnerName1,
      BusinessPartnerName2,
      TaxJurisdiction,
      TransportZone,
      FormOfAddress,
      SearchTerm1,
      SearchTerm2,

      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

      /* Associations */
      _BPProtectedAddress,
      _BusinessPartnerGov
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSPARTSCRIPTEDGROUPADDRESS",
"I_BUSPARTSCRIPTEDGRPADDRPROC",
"I_MASTERDATACHANGEPROCESS",
"I_SCRIPTEDORGANIZATIONADDRESS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERGOV",
"I_BUSPARTPROTECTEDADDRESSPROC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/