I_BusPartMobileNumberGov

@AbapCatalog.sqlViewName: 'IBPMOBILENUMGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BP Governance Telephone Number'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
@AccessControl.personalData.blocking: #REQUIRED
define view I_BusPartMobileNumberGov
  as select from I_BusPartMobileNumberProc

  association [1..1] to I_BusinessPartnerGov      as _BusinessPartner         on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
  association [0..1] to I_BPProtectedAddress      as _BPProtectedAddress      on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                              and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
      //I_BusPartTelephoneNumberProc

      //I_BusPartMobileNumberProc

  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      MobilePhoneCountry,
      IsDefaultPhoneNumber,
      //      CommNumberIsNotUsed,

      MobilePhoneNumber,
      //      CompleteTelephoneNumber,

      PhoneIsSMSEnabled,
      PhoneNumberType,
      ValidityStartDateTime,
      ValidityEndDateTime,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BusinessPartner,
      _BPProtectedAddress
}
where
  MDChgProcessSourceModified <> 'D'
  
union all

select from I_BPMobilePhoneNumber

association [1..1] to I_BusinessPartnerGov as _BusinessPartner    on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                  and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key AddressID                                   as AddressNumber,
  key OrdinalNumber,

      MobilePhoneCountry,
      //      CompleteTelephoneNumber,

      IsDefaultPhoneNumber,
      MobilePhoneNumber,
      PhoneIsSMSEnabled,
      PhoneNumberType,
      ValidityStartDateTime,
      ValidityEndDateTime,
      /* Associations */
      //I_BPMobilePhoneNumber


      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

      _BusinessPartner,
      _BPProtectedAddress
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPMOBILEPHONENUMBER",
"I_BUSPARTMOBILENUMBERPROC",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BPPROTECTEDADDRESS",
"I_BUSINESSPARTNERGOV",
"I_MASTERDATACHANGEPROCESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/