I_BusPartIndustryGov

@AbapCatalog.sqlViewName: 'IBPINDUSTRYGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'BP Industry Governance'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #COMPOSITE
define view I_BusPartIndustryGov
  as select from I_BusPartIndustryProc
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess

{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key IndustrySystemType,
  key IndustrySector,
      BusinessPartner,
      IsStandardIndustry,

      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BusinessPartnerGov
}
where
  MDChgProcessSourceModified <> 'D'

union all
select from I_BusinessPartnerIndustry
association [1..1] to I_BusinessPartnerGov as _BusinessPartnerGov on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key IndustrySystemType,
  key IndustrySector,
      BusinessPartner,
      IsStandardIndustry,

      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

      _BusinessPartnerGov
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERINDUSTRY",
"I_BUSPARTINDUSTRYPROC",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERGOV",
"I_MASTERDATACHANGEPROCESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/