I_BusPartIdentificationTP_2

//@AbapCatalog.sqlViewName: 'IBUPAIDTP2'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
//@ClientHandling.algorithm : #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Transactional View for I_BuPaIdentification'
define view entity I_BusPartIdentificationTP_2
  as select from I_BuPaIdentification as BusinessPartnerIdentification
  association        to parent I_BusinessPartnerTP_2 as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
//                                                                         and $projection.BPDrftUUID      = _BusinessPartner.BPDrftUUID

  association [0..1] to I_BusinessPartnerTP_2        as _BusinessPart    on  $projection.BusinessPartner = _BusinessPart.BusinessPartner
                                                                        // and $projection.BPDrftUUID      = _BusinessPart.BPDrftUUID

  association [0..1] to I_Country                    as _Country         on  $projection.Country = _Country.Country
  association [0..1] to I_Region                     as _Region          on  $projection.Country = _Region.Country
                                                                         and $projection.Region  = _Region.Region
  association [0..1] to I_BusPartIdentificationType  as _BusPartIdType   on  $projection.BPIdentificationType    = _BusPartIdType.BPIdentificationType
                                                                         and $projection.businesspartnercategory = _BusPartIdType.BusinessPartnerCategory

{
//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPDrftUUID,

//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPIdentificationDrftUUID,

  key BusinessPartner,
  key BPIdentificationType,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BPIdentificationNumber,
      BPIdnNmbrIssuingInstitute,
      BPIdentificationEntryDate,
      Country,
      Region,
      ValidityStartDate,
      ValidityEndDate,
      AuthorizationGroup,
      @ObjectModel.editableFieldFor: 'BPIdentificationType'
      BPIdentificationType                                               as BPIdnTypeForEditValue,
      @ObjectModel.editableFieldFor: 'BPIdentificationNumber'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BPIdentificationNumber                                             as BPIdnNumberForEditValue,
      _BusinessPart.BusinessPartnerCategory,
      _BusinessPartner.IsBusinessPurposeCompleted,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataControllerSet              as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController1                as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController2                as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController3                as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController4                as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController5                as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController6                as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController7                as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController8                as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController9                as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController10               as DataController10,
      _BusinessPartner,
      _BusinessPart._BusinessPartnerCategory as _BusinessPartnerCategory,
      _BusPartIdType,
      _Region,
      _Country,
      
      BusinessPartnerIdentification._BuPaIdentificationType as _BuPaIdentificationType
 //     _BPDataControllerUsage

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUPAIDENTIFICATION",
"I_BUSINESSPARTNERTP_2"
],
"ASSOCIATED":
[
"I_BUPAIDENTIFICATIONTYPE",
"I_BUSINESSPARTNERTP_2",
"I_BUSPARTCATEGORY",
"I_BUSPARTIDENTIFICATIONTYPE",
"I_COUNTRY",
"I_REGION"
],
"BASE":
[
"I_BUPAIDENTIFICATION",
"I_BUSINESSPARTNERTP_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/