I_BusPartContactPersonProcChgs

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BP Relationship Contact Person Process Changes'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity I_BusPartContactPersonProcChgs
  as select from           I_BusPartContactPersonProcess as _Current
    left outer to one join I_MDChangeProcessModelTable   as _ModelTable     on  _ModelTable.MDChgProcessModelTableName     = 'BUT051'
                                                                            and _ModelTable.MDChgProcessSrceObjectTypeCode = '1405'
    inner join             I_BusPartRelationshipProcess  as _BPRelationship on  _Current.MasterDataChangeProcess = _BPRelationship.MasterDataChangeProcess
                                                                            and _Current.MDChgProcessStep        = _BPRelationship.MDChgProcessStep
                                                                            and _Current.MDChgProcessSrceSystem  = _BPRelationship.MDChgProcessSrceSystem
                                                                            and _Current.MDChgProcessSrceObject  = _BPRelationship.MDChgProcessSrceObject
  association [1..1] to I_BusinessPartnerProcess    as _BusinessPartner          on  $projection.MasterDataChangeProcess    = _BusinessPartner.MasterDataChangeProcess
                                                                                 and $projection.MDChgProcessStep           = _BusinessPartner.MDChgProcessStep
                                                                                 and $projection.MDChgProcessSrceSystem     = _BusinessPartner.MDChgProcessSrceSystem
                                                                                 and (
                                                                                    $projection.MDChgProcessSrceBusPart1    = _BusinessPartner.MDChgProcessSrceObject
                                                                                    or $projection.MDChgProcessSrceBusPart2 = _BusinessPartner.MDChgProcessSrceObject
                                                                                  )
  association [0..*] to I_BusPartRelshpCategoryDesc as _RelationshipCategoryText on  $projection.RelationshipCategory        = _RelationshipCategoryText.RelationshipCategory
                                                                                 and $projection.BPRelshpCatIsInFwdDirection = _RelationshipCategoryText.BPRelshpCatIsInFwdDirection
{
  key _Current.MasterDataChangeProcess,
  key _Current.MDChgProcessStep,
  key _Current.MDChgProcessSrceSystem,
  key _Current.MDChgProcessSrceObject,
  key _ModelTable.MDChgProcessModelTableName,
  key cast ( '' as fieldname )                                                                                               as MDChangeProcessModelFieldName,
  key cast ( concat( _Current.MDChgProcessSrceSystem, concat( '%%', _Current.MDChgProcessSrceObject ))  as abap.char(1000) ) as MDChgProcessRecordObjectID,
      _BPRelationship.MDChgProcessSrceBusPart1,
      _BPRelationship.MDChgProcessSrceBusPart2,
      _BPRelationship.RelationshipCategory,
      @Semantics.booleanIndicator: true
      _BPRelationship.BPRelshpCatIsInFwdDirection,
      _BPRelationship.BP1AuthorizationGroup,
      _BPRelationship.BP2AuthorizationGroup,
      _Current.BP1DataControllerSet,
      _Current.BP1DataController1,
      _Current.BP1DataController2,
      _Current.BP1DataController3,
      _Current.BP1DataController4,
      _Current.BP1DataController5,
      _Current.BP1DataController6,
      _Current.BP1DataController7,
      _Current.BP1DataController8,
      _Current.BP1DataController9,
      _Current.BP1DataController10,
      _Current.BP2DataControllerSet,
      _Current.BP2DataController1,
      _Current.BP2DataController2,
      _Current.BP2DataController3,
      _Current.BP2DataController4,
      _Current.BP2DataController5,
      _Current.BP2DataController6,
      _Current.BP2DataController7,
      _Current.BP2DataController8,
      _Current.BP2DataController9,
      _Current.BP2DataController10,
      _ModelTable.MDChangeProcModelTableDesc,
      cast ('' as as4text )                                                                                                  as MDChangeProcessModelFieldDesc,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( 'BusPartRelContactPerson' as fieldname )                                                                         as MDChgProcModelNodeExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      cast( 'I_BusPartContactPersonProcTP' as fieldname )                                                                    as MDChgProcModTableExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_REL_PROCTP_CALC_EXIT'
      cast( '' as fieldname )                                                                                                as MDChgProcModFieldExternalName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_REL_PROCTP_CALC_EXIT'
      cast( '' as abap.char( 260 ) )                                                                                         as MDChgProcCurrentAttributeValue,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_REL_PROCTP_CALC_EXIT'
      cast( '' as abap.char( 260 ) )                                                                                         as MDChgProcPrevAttributeValue,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_REL_PROCTP_CALC_EXIT'
      cast( '' as boolean )                                                                                                  as MDChgProcessAttributeIsChanged,
      _Current.MDChgProcessSourceModified,
      concat_with_space(
            concat_with_space( _BPRelationship.BusinessPartnerName1,_RelationshipCategoryText.BusPartRelshpCatDescription,1)
          ,_BPRelationship.BusinessPartnerName2,1)                                                                           as MDChgProcessRecordObjectText,
      _BusinessPartner,
      _RelationshipCategoryText
}
where
     _Current.MDChgProcessSourceModified = 'I'
  or _Current.MDChgProcessSourceModified = 'D'

union all select from     I_BusPartContactPersonProcess as _Current
  inner join              I_BusPartRelationshipProcess  as _BPRelationship on  _Current.MasterDataChangeProcess = _BPRelationship.MasterDataChangeProcess
                                                                           and _Current.MDChgProcessStep        = _BPRelationship.MDChgProcessStep
                                                                           and _Current.MDChgProcessSrceSystem  = _BPRelationship.MDChgProcessSrceSystem
                                                                           and _Current.MDChgProcessSrceObject  = _BPRelationship.MDChgProcessSrceObject
  left outer to many join I_MDChangeProcessModelField   as _ModelField     on  _ModelField.MDChgProcessModelTableName     = 'BUT051'
                                                                           and _ModelField.MDChgProcessSrceObjectTypeCode = '1405'
  left outer to one join  dd03l                         as dd03l           on  dd03l.tabname   = 'BUT051'
                                                                           and dd03l.fieldname = _ModelField.MDChangeProcessModelFieldName
                                                                           and dd03l.as4local  = 'A'
                                                                           and dd03l.as4vers   = '0000'
  left outer to one join  dd04t                         as dd04t           on  dd04t.rollname   = dd03l.rollname
                                                                           and dd04t.as4local   = dd03l.as4local
                                                                           and dd04t.as4vers    = dd03l.as4vers
                                                                           and dd04t.ddlanguage = $session.system_language
association [1..1] to I_BusinessPartnerProcess    as _BusinessPartner          on  $projection.MasterDataChangeProcess    = _BusinessPartner.MasterDataChangeProcess
                                                                               and $projection.MDChgProcessStep           = _BusinessPartner.MDChgProcessStep
                                                                               and $projection.MDChgProcessSrceSystem     = _BusinessPartner.MDChgProcessSrceSystem
                                                                               and (
                                                                                  $projection.MDChgProcessSrceBusPart1    = _BusinessPartner.MDChgProcessSrceObject
                                                                                  or $projection.MDChgProcessSrceBusPart2 = _BusinessPartner.MDChgProcessSrceObject
                                                                                )
association [0..*] to I_BusPartRelshpCategoryDesc as _RelationshipCategoryText on  $projection.RelationshipCategory        = _RelationshipCategoryText.RelationshipCategory
                                                                               and $projection.BPRelshpCatIsInFwdDirection = _RelationshipCategoryText.BPRelshpCatIsInFwdDirection
{

  key _Current.MasterDataChangeProcess,
  key _Current.MDChgProcessStep,
  key _Current.MDChgProcessSrceSystem,
  key _Current.MDChgProcessSrceObject,
  key _ModelField.MDChgProcessModelTableName,
  key _ModelField.MDChangeProcessModelFieldName,
  key cast ( concat( _Current.MDChgProcessSrceSystem, concat( '%%', _Current.MDChgProcessSrceObject )) as abap.char(1000) ) as MDChgProcessRecordObjectID,
      _BPRelationship.MDChgProcessSrceBusPart1,
      _BPRelationship.MDChgProcessSrceBusPart2,
      _BPRelationship.RelationshipCategory,
      _BPRelationship.BPRelshpCatIsInFwdDirection,
      _BPRelationship.BP1AuthorizationGroup,
      _BPRelationship.BP2AuthorizationGroup,
      _Current.BP1DataControllerSet,
      _Current.BP1DataController1,
      _Current.BP1DataController2,
      _Current.BP1DataController3,
      _Current.BP1DataController4,
      _Current.BP1DataController5,
      _Current.BP1DataController6,
      _Current.BP1DataController7,
      _Current.BP1DataController8,
      _Current.BP1DataController9,
      _Current.BP1DataController10,
      _Current.BP2DataControllerSet,
      _Current.BP2DataController1,
      _Current.BP2DataController2,
      _Current.BP2DataController3,
      _Current.BP2DataController4,
      _Current.BP2DataController5,
      _Current.BP2DataController6,
      _Current.BP2DataController7,
      _Current.BP2DataController8,
      _Current.BP2DataController9,
      _Current.BP2DataController10,
      _ModelField.MDChangeProcModelTableDesc,
      case
        when _ModelField.MDChangeProcessModelFieldDesc is not initial
        then _ModelField.MDChangeProcessModelFieldDesc
        else dd04t.ddtext
      end                                                                                                                   as MDChangeProcessModelFieldDesc,
      cast( 'BusPartRelContactPerson' as fieldname )                                                                        as MDChgProcModelNodeExternalName,
      cast( 'I_BusPartContactPersonProcTP' as fieldname )                                                                   as MDChgProcModTableExternalName,
      cast( '' as fieldname )                                                                                               as MDChgProcModFieldExternalName,
      cast( '' as abap.char( 260 ) )                                                                                        as MDChgProcCurrentAttributeValue,
      cast( '' as abap.char( 260 ) )                                                                                        as MDChgProcPrevAttributeValue,
      cast( '' as boolean )                                                                                                 as MDChgProcessAttributeIsChanged,
      _Current.MDChgProcessSourceModified,
      concat_with_space(
             concat_with_space( _BPRelationship.BusinessPartnerName1,_RelationshipCategoryText.BusPartRelshpCatDescription,1)
           ,_BPRelationship.BusinessPartnerName2,1)                                                                         as MDChgProcessRecordObjectText,
      _BusinessPartner,
      _RelationshipCategoryText
}
where
  _Current.MDChgProcessSourceModified = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSPARTCONTACTPERSONPROCESS",
"I_BUSPARTRELATIONSHIPPROCESS",
"I_BUSPARTRELSHPCATEGORYDESC",
"I_MDCHANGEPROCESSMODELFIELD",
"I_MDCHANGEPROCESSMODELTABLE",
"DD03L",
"DD04T"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERPROCESS",
"I_BUSPARTRELSHPCATEGORYDESC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/