I_BusPartAddressUsageGov

@AbapCatalog.sqlViewName: 'IBPADDRUSAGEGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Basic view for BP address usage'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #COMPOSITE
define view I_BusPartAddressUsageGov
  as select from I_BusPartAddressUsageProc
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartner         on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key ValidityEndDate,
  key AddressUsage,
  key AddressNumber,
      BusinessPartner,
      ValidityStartDate,
      StandardUsage,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BusinessPartner
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_Businesspartneraddressusage
association [1..1] to I_BusinessPartnerGov as _BusinessPartner on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                               and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                               and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                               and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key ValidityEndDate,
  key AddressUsage,
  key AddressNumber,
      BusinessPartner,
      ValidityStartDate,
      StandardUsage,
      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,

      _BusinessPartner

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERADDRESSUSAGE",
"I_BUSPARTADDRESSUSAGEPROC",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERGOV",
"I_MASTERDATACHANGEPROCESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/