I_BusEvtSubBusObj

@AbapCatalog.sqlViewName: 'IBUSEVTSUBBUSOBJ'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Business Event Handling Subscribers'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
define view I_BusEvtSubBusObj
  as select from I_BusEvtSub
    cross join   I_SAPObjectTypeEventCode
  association [1..*] to I_BusinessObjectEventTask as _BusinessObjectEventTask on  _BusinessObjectEventTask.SAPObjectEventCode          = $projection.SAPObjectEventCode
                                                                              and _BusinessObjectEventTask.SAPObjectType               = $projection.SAPObjectType
                                                                              and _BusinessObjectEventTask.SAPObjectRepresentationType = 'SOA'
{

  key I_SAPObjectTypeEventCode.SAPObjectType,
  key I_SAPObjectTypeEventCode.SAPObjectEventCode,
  key I_BusEvtSub.BusEventSubscriberCode,
      I_BusEvtSub.BusinessEventSubscriberName,
      _BusinessObjectEventTask[1:inner].SAPObjectTypeName,
      _BusinessObjectEventTask[1:inner].SAPObjectTaskCode,
      _BusinessObjectEventTask[1:inner].SAPObjectTaskTypeName
}

union select from I_BusEvtSub
  cross join      I_BusinessEventBindingHeader
{

  key   I_BusinessEventBindingHeader.SAPObjectType,
  key   cast( upper (I_BusinessEventBindingHeader.EventOperation) as abap.char( 32 ))                                   as SAPObjectEventCode,
  key   I_BusEvtSub.BusEventSubscriberCode,
        I_BusEvtSub.BusinessEventSubscriberName,
        cast(I_BusinessEventBindingHeader.SAPObjectType as abap.char( 30 ))                                             as SAPObjectTypeName,
        cast(I_BusinessEventBindingHeader.EventOperation as abap.char( 30 ))                                            as SAPObjectTaskCode,
        concat_with_space( I_BusinessEventBindingHeader.SAPObjectType, I_BusinessEventBindingHeader.EventOperation, 1 ) as SAPObjectTaskTypeName
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSEVTSUB",
"I_BUSINESSEVENTBINDINGHEADER",
"I_BUSINESSOBJECTEVENTTASK",
"I_SAPOBJECTTYPEEVENTCODE"
],
"ASSOCIATED":
[
"I_BUSINESSOBJECTEVENTTASK"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/