I_BudgetPeriodHierarchyNode

@AbapCatalog.sqlViewName: 'IBDGTPDHN'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Budget Period Hierarchy Node'

@VDM.viewType: #BASIC
@Hierarchy.parentChild:[
{ recurse:          {   parent: 'ParentNode',   child:  'HierarchyNode'   },
  siblingsOrder:    {   by: 'HierarchyNodeSequence',    direction: 'ASC'   },
  directory:        '_Hierarchy'
  }]
@Analytics: { dataExtraction: {enabled:true} }
@ObjectModel: {
     dataCategory: #HIERARCHY,
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #A,
         sizeCategory: #XL
     }
}
@ObjectModel.representativeKey: 'HierarchyNode'
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE ]

define view I_BudgetPeriodHierarchyNode
  as select from hrrp_node_n

  association [0..*] to I_BudgetPeriodHierarchyNodeT as _Text         on  $projection.BudgetPeriodHierarchy = _Text.BudgetPeriodHierarchy
                                                                      and $projection.HierarchyNode         = _Text.HierarchyNode
                                                                      and $projection.BudgetPeriod          = '' // just to show that this association is only to be followed if BudgetPeriods center is blank


  association [0..1] to I_BudgetPeriod               as _BudgetPeriod on  $projection.BudgetPeriod = _BudgetPeriod.BudgetPeriod

  association [1..1] to I_BudgetPeriodHierarchy      as _Hierarchy    on  $projection.BudgetPeriodHierarchy = _Hierarchy.BudgetPeriodHierarchy
                                                                      and $projection.ValidityEndDate       = _Hierarchy.ValidityEndDate

{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( hrrp_node_n.hryid_42 as fmis_hryid_budgetperiod preserving type) as BudgetPeriodHierarchy,
      @ObjectModel.text.association: '_Text'
  key hrrp_node_n.hrynode                                                 as HierarchyNode,
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @Semantics.businessDate.to: true
  key cast( hrrp_node_n.hryvalto as fis_datbi preserving type )           as ValidityEndDate,
      hrrp_node_n.parnode                                                 as ParentNode,
      @VDM.lifecycle.status:    #DEPRECATED
      cast( '000000000000001' as hryversn )                               as HierarchyVersion,
      @Semantics.businessDate.from: true
      cast( hrrp_node_n.hryvalfrom as fis_datab preserving type)          as ValidityStartDate,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BudgetPeriodStdVH',
                     element: 'BudgetPeriod' }
        }]
      @ObjectModel.foreignKey.association: '_BudgetPeriod'
      @Consumption.filter.businessDate.at:true
      hrrp_node_n.budget_pd                                               as BudgetPeriod,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'HierarchyNodeSequence'
      concat(hrrp_node_n.hryseqnbr, hrrp_node_n.hrynode)                  as SequenceNumber,
      hrrp_node_n.hryseqnbr                                               as HierarchyNodeSequence,
      hrrp_node_n.hrylevel                                                as HierarchyNodeLevel,
      hrrp_node_n.nodetype                                                as NodeType,

      _Text,
      _BudgetPeriod,
      _Hierarchy

}
where

      hrrp_node_n.nodetype <> 'D'
  and hrrp_node_n.hrytyp  =  '0114'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE_N"
],
"ASSOCIATED":
[
"I_BUDGETPERIOD",
"I_BUDGETPERIODHIERARCHY",
"I_BUDGETPERIODHIERARCHYNODET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/