I_BudgetDocumentItmSearchBasic

@AbapCatalog.sqlViewName: 'IBDGTDOCITMESH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL,
                          serviceQuality: #D,
                          sizeCategory: #L }
@EndUserText.label: 'Budget Document Item Search Basic'
define view I_BudgetDocumentItmSearchBasic
  as select from acdocp
  //  association [1..1] to I_BudgetDocument           as _BudgetDocument          on  $projection.ControllingArea    = _BudgetDocument.ControllingArea

  //                                                                               and $projection.BudgetDocumentYear = _BudgetDocument.BudgetDocumentYear

  //                                                                               and $projection.BudgetDocument     = _BudgetDocument.BudgetDocument

  association [1..1] to I_CompanyCode              as _CompanyCode             on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_FinancialManagementArea  as _FinMgmtArea             on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea
  association [1..1] to I_Currency                 as _TransactionCurrency     on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_Currency                 as _GlobalCurrency          on  $projection.GlobalCurrency = _GlobalCurrency.Currency
  association [0..1] to I_Currency                 as _CompanyCodeCurrency     on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_Currency                 as _ControllingAreaCurrency on  $projection.ControllingObjectCurrency = _ControllingAreaCurrency.Currency
  association [1..1] to I_FiscalYearForCompanyCode as _LedgerFiscalYear        on  $projection.FiscalYear  = _LedgerFiscalYear.FiscalYear
                                                                               and $projection.CompanyCode = _LedgerFiscalYear.CompanyCode
  association [1..1] to I_ControllingArea          as _ControllingArea         on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1..1] to I_BudgetPlanningCategory   as _PlanningCategory        on  $projection.PlanningCategory = _PlanningCategory.PlanningCategory
  association [0..1] to I_BudgetProcess            as _BudgetProcess           on  $projection.BudgetProcess = _BudgetProcess.BudgetProcess
  association [0..1] to I_BudgetingType            as _BudgetingType           on  $projection.BudgetingType = _BudgetingType.BudgetingType
{
  key kokrs                                             as ControllingArea,
  key ryear                                             as BudgetDocumentYear,
  key awref                                             as BudgetDocument,
  key record                                            as BudgetDocumentItem,
      @ObjectModel.foreignKey.association: '_PlanningCategory'
      category                                          as PlanningCategory,
      rbukrs                                            as CompanyCode,
      racct                                             as GLAccount,
      rcntr                                             as CostCenter,
      rfarea                                            as FunctionalArea,
      ryear                                             as FiscalYear,
      fikrs                                             as FinancialManagementArea,
      rfund                                             as Fund,
      rbudget_pd                                        as BudgetPeriod,
      rgrant_nbr                                        as GrantID,
      cast( ps_posid as ps_posid_edit )                 as WBSElement,
      cast( ps_psp_pnr as ps_s4_pspnr )                 as WBSElementInternalID,
      cast( ps_pspid as ps_pspid_edit )                 as Project,
      cast( ps_prj_pnr as ps_s4_proj_pspnr )            as ProjectInternalID,
      poper                                             as FiscalPeriod,
      budget_process                                    as BudgetProcess,
      budget_subcategory                                as BudgetingType,

      //Transaction currency

      @Semantics.currencyCode:true
      cast( rwcur as fis_rwcur preserving type )        as TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( wsl as fis_wsl preserving type )            as AmountInTransactionCurrency,

      //Company code currency

      @Semantics.currencyCode:true
      cast( rhcur as fis_hwaer preserving type )        as CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast( hsl as fis_hsl preserving type )            as AmountInCompanyCodeCurrency,

      //Global currency

      @Semantics.currencyCode:true
      cast( rkcur as fis_rkcur preserving type )        as GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      cast( ksl as fis_ksl preserving type )            as AmountInGlobalCurrency,

      // Controlling Object Currency

      @Semantics.currencyCode:true
      cast( rco_ocur as fins_co_ocur preserving type )  as ControllingObjectCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'ControllingObjectCurrency'
      cast( co_osl as fins_vco_ocur12 preserving type ) as AmountInObjectCurrency,

      //      _BudgetDocument,

      _PlanningCategory,
      _BudgetingType,
      _BudgetProcess,
      _CompanyCode,
      _CompanyCodeCurrency,
      _ControllingArea,
      _ControllingAreaCurrency,
      _FinMgmtArea,
      _GlobalCurrency,
      _LedgerFiscalYear,
      _TransactionCurrency
}
where
     budget_process = 'SEND' or budget_process = 'RECV'
  or budget_process = 'RETN' or budget_process = 'SUPL'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ACDOCP"
],
"ASSOCIATED":
[
"I_BUDGETINGTYPE",
"I_BUDGETPLANNINGCATEGORY",
"I_BUDGETPROCESS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CURRENCY",
"I_FINANCIALMANAGEMENTAREA",
"I_FISCALYEARFORCOMPANYCODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/