I_BkAcctIntIDVH

@AbapCatalog: {
  sqlViewName: 'IBKACCTINTIDVH',
  compiler.compareFilter: true
}

@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  usageType: {
    serviceQuality: #B,
    sizeCategory:   #S,
    dataClass:      #CUSTOMIZING
  }
}
@ObjectModel.dataCategory:#VALUE_HELP
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #BASIC
@EndUserText.label: 'Technical ID'
@Search.searchable: true

@UI.headerInfo: {
  typeName:       'Bank Account',
  typeNamePlural: 'Bank Accounts',
  typeImageUrl:   'sap-icon://appointment-2',

  title:          { value: 'BankAccountInternalID' }
}

@Consumption.ranked: true
@AbapCatalog.preserveKey:true 
@ObjectModel.representativeKey: 'BankAccountInternalID'
@AccessControl.personalData.blocking: true

/* Comment of Usage
There are several bank account value helps provided.
This cds view will return bank account with inactive bank accounts and all activated ones.
If it does not meet your requirment, you may check below value help CDS Views.
I_BankAccountVH
I_BankAccountStdVH
I_BankAcctIdVH
C_BankAcctIdVH
C_BankAccountVH

I_BankAcctNumberVH
*/

define view I_BkAcctIntIDVH
  as select from    fclm_bam_amd        as amd
    left outer to one join fclm_bam_amd_t      as desc    on  amd.acc_id        =  desc.acc_id
                                                   and amd.revision      =  desc.revision
                                                   and desc.langu        = $session.system_language
                                                   and desc.deleted_flag <> 'X'
    left outer to one join bnka                as bank    on  amd.banks = bank.banks
                                                   and amd.bankl = bank.bankl
{
      @UI.lineItem: [
       { position: 1, importance: #HIGH }
       ]
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
  key amd.acc_id               as BankAccountInternalID,
      @UI.lineItem: [
       { position: 2, importance: #HIGH }
       ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 1, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.acc_num              as BankAccountNumber,
      @UI.lineItem: [
      { position: 3, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 2, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      desc.description         as BankAccountDescription,
      @UI.lineItem: [
      { position:4, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 3, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.waers                as BankAccountCurrency,
      @UI.lineItem: [
      { position: 5, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 4, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.bukrs                as CompanyCode,
      @UI.lineItem: [
      { position: 6, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 5, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.acc_type_id          as BankAccountType,
      @UI.lineItem: [
      { position: 7, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 6, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.bankl                as Bank,
      @UI.lineItem: [
      { position: 8, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 7, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.banks                as BankCountry,
      @UI.lineItem: [
      { position: 9, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 8, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      amd.iban                 as IBAN,
      @UI.lineItem: [
      { position: 10, importance: #HIGH }
      ]
      @UI.fieldGroup: [
        { qualifier: 'Bank Account', position: 9, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      bank.swift               as SWIFTCode
}
where
  (
        amd.revision     =  '0000'
    and amd.status <> '99'
  )
  or(
        amd.revision     =  '0000'
    and amd.open_request_id  is not initial
    and amd.status = '99'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BNKA",
"FCLM_BAM_AMD",
"FCLM_BAM_AMD_T"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/