I_BankForBusinessPartner

@AbapCatalog.sqlViewName: 'IBANKFORBP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank Master for Business Partner'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'BankInternalID'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #B
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.privilegedAssociations:  [ '_Address', '_AddressDefaultRepresentation' ]
@Search.searchable: true
define view I_BankForBusinessPartner
  as select from bnka
  association [0..1] to I_Address             as _Address                      on  $projection.AddressID = _Address.AddressID
  association [0..1] to I_Region              as _Region                       on  $projection.Region      = _Region.Region
                                                                               and $projection.BankCountry = _Region.Country
  association [0..1] to I_Country             as _Country                      on  $projection.BankCountry = _Country.Country

  association [0..1] to I_OrganizationAddress as _AddressDefaultRepresentation on  $projection.AddressID                                   = _AddressDefaultRepresentation.AddressID
                                                                               and _AddressDefaultRepresentation.AddressRepresentationCode is initial

{
      @ObjectModel.foreignKey.association: '_Country'
  key banks as BankCountry,
      @ObjectModel.text.element: 'BankName'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
  key bankl as BankInternalID,
      erdat as CreationDate,
      ernam as CreatedByUser,
      @Semantics.text: true
      banka as BankName,
      provz as Region,
      stras as StreetName,
      ort01 as CityName,
      swift as SWIFTCode,
      bgrup as BankNetworkGrouping,
      xpgro as IsPostBankAccount,
      loevm as IsMarkedForDeletion,
      bnklz as Bank,
      pskto as PostOfficeBankAccount,
      brnch as Branch,
      chkme as CheckDigitCalculationMethod,
      vers  as BankDataFileFormat,
      adrnr as AddressID,
      _Address,
      _Region,
      _Country,
      _AddressDefaultRepresentation
}
where
     loevm = ''
  or loevm = ' ';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BNKA"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_COUNTRY",
"I_ORGANIZATIONADDRESS",
"I_REGION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/