I_BankAcctChangeRequest

@AbapCatalog.sqlViewName: 'IBAMREQ'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank Account Change Request'
@VDM.viewType: #BASIC
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #B
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: ['SQL_DATA_SOURCE','CDS_MODELING_DATA_SOURCE']

define view I_BankAcctChangeRequest
  as select from fclm_bam_req as cr
  association [1..*] to I_RequestWithBankAccount as _Bankaccount       on  $projection.BankAccountChangeRequest = _Bankaccount.BankAccountChangeRequest
  association [0..1] to I_BankAcctReqStatusText  as _requestStatusText on  $projection.BankAccountChangeRequestStatus = _requestStatusText.BankAccountChangeRequestStatus
                                                                       and _requestStatusText.Language                = $session.system_language
  association [0..1] to I_ActionOnBankAcctText   as _actionText        on  $projection.BankAccountAction = _actionText.BankAccountAction
                                                                       and _actionText.Language          = $session.system_language
{

  key   cr.request_id                                                                              as BankAccountChangeRequest,
        cr.title                                                                                   as BankAcctChangeReqHeadingText,
        cr.account_action                                                                          as BankAccountAction,
        _actionText.BankAccountActionText                                                          as BankAccountActionText,

        cr.request_status                                                                          as BankAccountChangeRequestStatus,
        _requestStatusText.BankAccountReqStatusText                                                as BankAccountReqStatusText,

        cr.created_by                                                                              as CreatedByUser,
        cr.created_on                                                                              as CreationDate,
        cr.duedate                                                                                 as BankAcctChangeRequestDueDate,
        cr.lastchged_by                                                                            as LastChangedByUser,
        cr.request_process                                                                         as BankAcctRequestProcess,

        cr.request_step                                                                            as BankAccountChangeRequestStep,
        cr.lastchged_on                                                                            as LastChangeDate,
        cr.lastchged_tm                                                                            as LastChangeTime,
        cr.created_tm                                                                              as CreationTime,
        cr.bypass_check_mass                                                                       as ChangeRequestIsBypassCheck,
        cast ( case when bypass_check_mass = 'X' then '' else 'X' end as boolean preserving type ) as ChgReqBypassChkIsHidn,
        _Bankaccount

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACTIONONBANKACCTTEXT",
"I_BANKACCTREQSTATUSTEXT",
"FCLM_BAM_REQ"
],
"ASSOCIATED":
[
"I_ACTIONONBANKACCTTEXT",
"I_BANKACCTREQSTATUSTEXT",
"I_REQUESTWITHBANKACCOUNT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/