I_BankAccountValidLinkage

@EndUserText.label: 'Bank Account Valid Linkages'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IFIBAMVLINKAGE'
@ObjectModel.representativeKey: 'HouseBankAccount'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
define view I_BankAccountValidLinkage
  as select from fclm_bam_aclink2 as hba
    inner join   fclm_bam_amd     as acc on  acc.acc_id   = hba.acc_id
                                         and hba.revision = acc.revision
{
  key  hba.bukrs    as CompanyCode,
  key  hba.hbkid    as HouseBank,
  key  hba.hktid    as HouseBankAccount,
       hba.acc_id   as BankAccountInternalID,
       acc.acc_num  as BankAccountNumber,
       hba.valid_to as ValidityEndDate
}
where
           hba.herku      =  ''
  and      hba.hbkid      <> ''
  and      hba.hktid      <> ''
  and      hba.is_reused  =  ''
  and      hba.revision   =  '0000'
  and      hba.valid_from <= $session.system_date
  and(
           acc.status     =  '15' //Closed in System

    and    acc.valid_to   =  hba.valid_to
    or(
      (
           acc.status     =  '02' //Active

        or acc.status     =  '09' //Marked for Closing

        or acc.status     =  '10' //To Be Closed

        or acc.status     =  '11' //Closed at Bank

      )
      and  hba.valid_to   >= $session.system_date
    )
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FCLM_BAM_ACLINK2",
"FCLM_BAM_AMD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/