I_BankAccountSetting

@AbapCatalog.sqlViewName: 'IBACCEBSCONFIG'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Bank Account and EBS Integration Setting'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_BankAccountSetting
  as select from fclm_acc_bs_conf as config
  association [0..1] to I_CashBalancePostingTypeText  as _BankStatementPostingType     on  $projection.BankStatementPostingType = _BankStatementPostingType.BankStatementPostingType
                                                                                       and _BankStatementPostingType.Language   = $session.system_language
  association [0..1] to I_CashBalanceTransferModeText as _BankStatementTransferMode    on  $projection.BankStatementTransferMode = _BankStatementTransferMode.BankStatementTransferMode
                                                                                       and _BankStatementTransferMode.Language   = $session.system_language
  association [0..1] to I_BankStatementForwardingText as _BankStatementForwarding      on  $projection.BankStatementForwardingType = _BankStatementForwarding.BankStatementForwardingType
                                                                                       and _BankStatementForwarding.Language       = $session.system_language
  association [0..1] to I_IntradayBkStmntPostgTxt     as _IntradayBankStatementPosting on  $projection.IntradayBankStatementPosting = _IntradayBankStatementPosting.IntradayBankStatementPosting
                                                                                       and _IntradayBankStatementPosting.Language   = $session.system_language
{
  key config.acc_id               as BankAccountInternalID,
      config.valid_from           as ValidityStartDate,
      config.valid_to             as ValidityEndDate,
      @ObjectModel.text.element    : ['BankStatementPostingTypeText']
      config.bs_post_cat          as BankStatementPostingType,
      @ObjectModel.text.element    : ['BankStatementTransferModeText']
      config.bs2fqm_mode          as BankStatementTransferMode,
      config.flag_epic            as InternalAPIBalanceIsEnabled,
      config.flag_import          as ExcelImportBalanceIsEnabled,
      config.flag_manual          as ManualInputBalanceIsEnabled,
      @ObjectModel.text.element    : ['BankStatementForwardingText']
      config.bs_forwarding        as BankStatementForwardingType,
      @ObjectModel.text.element    : ['IntradayBkStatementPostingText']
      config.intraday_bs_post_cat as IntradayBankStatementPosting,
      _BankStatementPostingType.BankStatementPostingTypeText,
      _BankStatementTransferMode.BankStatementTransferModeText,
      _BankStatementForwarding.BankStatementForwardingText,
      _IntradayBankStatementPosting.IntradayBkStatementPostingText,
      _BankStatementTransferMode,
      _BankStatementForwarding,
      _IntradayBankStatementPosting
}
where
      valid_from <= $session.system_date
  and valid_to   >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANKSTATEMENTFORWARDINGTEXT",
"I_CASHBALANCEPOSTINGTYPETEXT",
"I_CASHBALANCETRANSFERMODETEXT",
"I_INTRADAYBKSTMNTPOSTGTXT",
"FCLM_ACC_BS_CONF"
],
"ASSOCIATED":
[
"I_BANKSTATEMENTFORWARDINGTEXT",
"I_CASHBALANCEPOSTINGTYPETEXT",
"I_CASHBALANCETRANSFERMODETEXT",
"I_INTRADAYBKSTMNTPOSTGTXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/