I_BankAccountMultipleLinkage

@EndUserText.label: 'Bank Account Multi Linkages'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IFIBAMMLINKAGE'
@ObjectModel.representativeKey: 'HouseBankAccount'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE 
@Metadata.allowExtensions:true
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
define view I_BankAccountMultipleLinkage as select from fclm_bam_aclink2 as hba
inner join fclm_bam_amd as account on account.acc_id = hba.acc_id and account.revision = '0000'
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_Housebank   as _HouseBank   on $projection.HouseBank = _HouseBank.HouseBank and $projection.CompanyCode = _HouseBank.CompanyCode
association [0..1] to I_HouseBankAccount as _HouseBankAccount on $projection.CompanyCode = _HouseBankAccount.CompanyCode
and $projection.HouseBank = _HouseBankAccount.HouseBank
and $projection.HouseBankAccount = _HouseBankAccount.HouseBankAccount
 {
//key herku  as BankAccountLinkageRemoteSystem,

@ObjectModel.foreignKey.association: '_CompanyCode' //Inserted by VDM CDS Suite Plugin

key hba.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_HouseBank' //Inserted by VDM CDS Suite Plugin

key hba.hbkid as HouseBank,
key hba.hktid as HouseBankAccount,
key hba.valid_from as ValidityStartDate,
hba.bankn as BankAccount,
account.acc_num as BankAccountNumber,
hba.valid_to as ValidityEndDate,
//key remoteaccount as BankAcctLinkageRemoteAccount,

hba.acc_id as BankAccountInternalID, 
hba.bnkn2 as BankAccountAlternative, 
hba.dtaai as DataMedExchangeIdentification,
hba.refzl as ReferenceInfo,
hba.hkont as GLAccount,
_CompanyCode,
_HouseBank,
_HouseBankAccount
} 
where hba.revision = '0000' and hba.herku = '' and hba.is_reused <> 'X'
and ( account.status       =  '02' //Active

    or account.status       =  '09' //Marked for Closing

    or account.status       =  '10' //To Be Closed

    or account.status       =  '11' //Closed at Bank

    or account.status       =  '15' //Closed in System

   )
                    
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"FCLM_BAM_ACLINK2",
"FCLM_BAM_AMD"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_HOUSEBANK",
"I_HOUSEBANKACCOUNT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/