I_BankAccTwoPersonReq

@AbapCatalog.sqlViewName: 'IBKACCTPREQ'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank Account Two Person mode request'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
define view I_BankAccTwoPersonReq as select from fclm_bam_req as Req 
inner join fclm_bam_reqacnt as _ReqAcct on Req.request_id = _ReqAcct.request_id
inner join fclm_bam_amd as _Acct on _ReqAcct.acc_id = _Acct.acc_id and _ReqAcct.revision = _Acct.revision
left outer to one join fclm_bam_amd_t as _AcctDescrption on _Acct.acc_id = _AcctDescrption.acc_id and _Acct.revision = _AcctDescrption.revision and _AcctDescrption.langu = $session.system_language and _AcctDescrption.deleted_flag <> 'X'
left outer to one join fclm_bam_rev as _Rev on _ReqAcct.acc_id = _Rev.acc_id and _Rev.rev_status = '03'

{

 key Req.request_id as BankAccountChangeRequest,
 key _ReqAcct.acc_id as BankAccountInternalID,
 key _Acct.revision as BankAccountRevision,    
     Req.account_action as BankAccountAction,  
     Req.title as BankAcctChangeReqHeadingText,
     Req.created_on as CreationDate,
     Req.created_tm as CreationTime,
     Req.created_by as CreatedByUser,     
     _Acct.banks as BankCountry,
     _Acct.bankl as Bank,
     _Acct.bukrs as CompanyCode,
     _Acct.waers as BankAccountCurrency,
     _Acct.status as BankAccountStatus,
     _Acct.acc_num as BankAccountNumber,
     _Acct.acc_type_id as BankAccountType,
     _Acct.control_key as BankControlKey,
     _AcctDescrption.description as BankAccountDescription,     

     _Rev.revision as BankAccountActivatedRevision,
     _Rev.activated_seq as BankAccountActivatedSequence
     
  
}where Req.request_process = '02'
and Req.created_by <> $session.user
and Req.request_status = '05'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FCLM_BAM_AMD",
"FCLM_BAM_AMD_T",
"FCLM_BAM_REQ",
"FCLM_BAM_REQACNT",
"FCLM_BAM_REV"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/