I_BankAccLimitTP

@AbapCatalog: {
    sqlViewName: 'IBANKACCLIMTP',
    compiler.compareFilter: true
}

@EndUserText.label: 'Bank Account Limit BO active and draft'

@VDM:{
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type:#SAP_INTERNAL_API
}

@ObjectModel: {
    writeDraftPersistence: 'BANKACCLIMWD',
    createEnabled: 'EXTERNAL_CALCULATION',
    updateEnabled: true,
    deleteEnabled: true,
    semanticKey: [ 'BankAccountInternalID', 'OverdraftLimit' ],
    usageType: {
        sizeCategory: #M,
        serviceQuality: #C,
        dataClass: #MASTER
    }
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.allowExtensions: true
define view I_BankAccLimitTP
  as select from fclm_bam_amd_lim as AccountLim
  association [1..1] to I_BankAccountTP as _Account on  $projection.BankAccountInternalID = _Account.BankAccountInternalID
                                                    and $projection.BankAccountRevision   = _Account.BankAccountRevision
{
      @ObjectModel: {
        readOnly: true
      //        foreignKey.association: '_Account'

      }
  key acc_id                     as BankAccountInternalID,
      @ObjectModel: {
        readOnly: true,
        foreignKey.association: null
      }
  key lim_id                     as OverdraftLimit,
      @ObjectModel: {
        readOnly:  true
      }
  key revision                   as BankAccountRevision,
      @ObjectModel: {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      AccountLim.lim_id          as OverdraftLimitForEdit,

      @ObjectModel: {
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      valid_from                 as OverdraftLimitStartDate,

      @ObjectModel: {
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      valid_to                   as OverdraftLimitEndDate,

      @ObjectModel: {
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      @Semantics.amount.currencyCode: 'OverdraftLimitCurrency'
      amount                     as OverdraftLimitAmount,

      @ObjectModel: {
        readOnly:  'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      @Semantics.currencyCode: true
      waers                      as OverdraftLimitCurrency,

      @ObjectModel: {
        readOnly: true
      }
      @Consumption: {
        hidden: true
      }
      deleted_flag               as IsMarkedForDeletion,
      

      @ObjectModel: {
        association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
        }
      _Account
}
where
  deleted_flag <> 'X';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FCLM_BAM_AMD_LIM"
],
"ASSOCIATED":
[
"I_BANKACCOUNTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/