I_BR_NFTextsAggregation

@AbapCatalog.sqlViewName: 'IBRNFTEXTSAGGREG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Brazil Nota Fiscal Texts Aggregation'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_BR_NFTextsAggregation
  as select from I_BR_NFTexts
  association [0..1] to I_BR_NFTextSource as _BR_NFTextSource on _BR_NFTextSource.BR_NFTextSource = $projection.BR_NFMessageIsItemLinked
{
  key BR_NotaFiscal,
  key BR_NotaFiscalItem,
  key BR_NFTextType,
  key BR_NFTextSequenceNumber,
      BR_NFText,
      @ObjectModel.foreignKey.association: '_BR_NFTextSource'
      case when BR_NotaFiscalItem = '000000' then ''
           else 'X' end as BR_NFMessageIsItemLinked,
      _BR_NFTextType,
      _BR_NFTextSource
}
union all select from I_BR_NFTextsCompatibility
association [0..1] to I_BR_NFTextSource as _BR_NFTextSource on _BR_NFTextSource.BR_NFTextSource = $projection.BR_NFMessageIsItemLinked
{
  key BR_NotaFiscal,
  key BR_NotaFiscalItem,
  key BR_NFTextType,
  key concat(BR_NFMessageSequenceNumber, BR_NFMessageLineNumber) as BR_NFTextSequenceNumber,
      BR_NFMessageText  as BR_NFText,
      @ObjectModel.foreignKey.association: '_BR_NFTextSource'
      case when BR_NotaFiscalItem = '000000' or 
                BR_NotaFiscalItem is null 
                then ''
           else 'X' end as BR_NFMessageIsItemLinked,
      _BR_NFTextType,
      _BR_NFTextSource
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BR_NFTEXTS",
"I_BR_NFTEXTSCOMPATIBILITY"
],
"ASSOCIATED":
[
"I_BR_NFTEXTSOURCE",
"I_BR_NFTEXTTYPE"
],
"BASE":
[
"I_BR_NFTEXTS"
],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/