I_BR_McgnCompnTypeText

DDL: I_BR_MCGNCOMPNTYPETEXT Type: view BASIC

Microgen Compensation type text

I_BR_McgnCompnTypeText is a Basic CDS View that provides data about "Microgen Compensation type text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields MicrogenCompnGrpType, Language. It has 1 association to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (17)

NameValueLevelField
AbapCatalog.sqlViewName IMGACOMPTYPTXT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AbapCatalog.dataMaintenance #RESTRICTED view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Microgen Compensation type text view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.representativeKey MicrogenCompnGrpType view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #BASIC view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY MicrogenCompnGrpType
KEY Language
MicrogenCompnGrpTypeDesc
DomainValue dd07t domvalue_l
_MicrogenCompType _MicrogenCompType
_Language _Language 
@AbapCatalog: { sqlViewName: 'IMGACOMPTYPTXT',
                compiler.compareFilter: true ,
                preserveKey: true,
                dataMaintenance: #RESTRICTED }
                
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Microgen Compensation type text'
             
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { dataCategory: #TEXT ,
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
                supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT] ,
                representativeKey: 'MicrogenCompnGrpType',
                usageType: { serviceQuality: #A ,
                             dataClass: #META ,
                             sizeCategory: #S } }                              

@Search.searchable: true
@VDM:{ lifecycle.contract.type: #SAP_INTERNAL_API,
       viewType: #BASIC }
       
define view  I_BR_McgnCompnTypeText 
     as select from dd07t
     
association to parent I_BR_McgnCompnType  as _MicrogenCompType   on $projection.MicrogenCompnGrpType = _MicrogenCompType.MicrogenCompnGrpType
association [0..1] to I_Language          as _Language           on $projection.Language = _Language.Language  
{
      @ObjectModel:{ foreignKey.association: '_MicrogenCompType' ,
                     text.element: ['MicrogenCompnGrpTypeDesc'] }
  key cast(dd07t.domvalue_l as ecomp_typ)                                     as MicrogenCompnGrpType,   
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast( dd07t.ddlanguage as spras preserving type )                       as Language,        
      @Search:{ defaultSearchElement: true,
                fuzzinessThreshold: 0.8,
                ranking: #HIGH }
      @Semantics.text: true     
    
      cast ( dd07t.ddtext     as e_mg_br_comptype_txt_vdm preserving type )   as MicrogenCompnGrpTypeDesc, 
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                        as DomainValue,
            
      //Association

     _MicrogenCompType,
     _Language

}
where
      dd07t.domname  = 'ECOMP_TYP'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_BR_MCGNCOMPNTYPE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More