I_BPSupplierPartnerFunctionTP

@AbapCatalog.sqlViewName: 'IBPSUPPARTFUNCTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Supplier Partner Function TP'

//@ObjectModel.transactionalProcessingEnabled : true

@ObjectModel.writeDraftPersistence: 'BPsupl_pf_d'
@ObjectModel.draftEnabled:true
@VDM.viewType: #TRANSACTIONAL
@Search.searchable: true
//@ClientDependent: true

@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

define view I_BPSupplierPartnerFunctionTP
  as select from I_BPSupplierPartnerFunction as SupplierPartnerFunc
  association [1..1] to I_BusinessPartnerPurgOrgTP as _BPPurchasingOrg     on  $projection.PurchasingOrganization = _BPPurchasingOrg.PurchasingOrganization
                                                                           and $projection.BusinessPartner        = _BPPurchasingOrg.BusinessPartner
  association [1..1] to I_BusinessPartnerTP        as _BusinessPartner     on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_PartnerFunctionText      as _PartnerFunctionText on  $projection.PartnerFunctionForEdit = _PartnerFunctionText.PartnerFunction
                                                                           and _PartnerFunctionText.Language      = $session.system_language
  
{

  key   SupplierPartnerFunc.BusinessPartner                                                                                                            as BusinessPartner,
  key   SupplierPartnerFunc.PurchasingOrganization                                                                                                     as PurchasingOrganization,
  key   SupplierPartnerFunc.PartnerFunction                                                                                                            as PartnerFunction,
  key   SupplierPartnerFunc.PartnerCounter                                                                                                             as PartnerCounter,

        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.BusinessPartner                                                                                                            as BusinessPartnerForEdit,
        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.PurchasingOrganization                                                                                                     as PurchasingOrganizationForEdit,
        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.PartnerFunction                                                                                                            as PartnerFunctionForEdit,
        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.PartnerCounter                                                                                                             as PartnerCounterForEdit,

        @Search.defaultSearchElement: true
        @Search.fuzzinessThreshold: 0.8
        @Search.ranking: #HIGH
        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.Supplier                                                                                                                   as Supplier,

        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        _BusinessPartner.BusinessPartnerGrouping                                                                                                       as BusinessPartnerGrouping,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'        
        SupplierPartnerFunc.ContactPerson                                                                                                              as ContactPerson,
        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.DefaultPartner                                                                                                             as DefaultPartner,
        SupplierPartnerFunc.PartnerFunctionType                                                                                                        as PartnerFunctionType,
        @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        SupplierPartnerFunc.ReferenceSupplier                                                                                                          as ReferenceSupplier,
        SupplierPartnerFunc.Plant                                                                                                                      as Plant,
        SupplierPartnerFunc.SupplierSubrange                                                                                                           as SupplierSubrange,
        _SupplierToBusinessPartner._BusinessPartner.BusinessPartner                                                                                    as Partner,
        coalesce(_SupplierToBusinessPartner._BusinessPartner.BusinessPartnerName, _SupplierToBusinessPartner._BusinessPartner.BusinessPartnerFullName) as BusinessPartnerName,
        _PartnerFunctionText.PartnerFunctionName,   
        @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT]
        _BPPurchasingOrg,
        @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT]
        _BusinessPartner,
        _PartnerFunctionText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPSUPPLIERPARTNERFUNCTION",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERTP",
"I_PARTNERFUNCTIONTEXT",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERPURGORGTP",
"I_BUSINESSPARTNERTP",
"I_PARTNERFUNCTIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/