I_BPEmailAddress

@AbapCatalog.sqlViewName: 'IBPEMAILADDR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Email Core View'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
define view I_BPEmailAddress 
    as select from I_AddressEmailAddress_2
                   inner join but020 on I_AddressEmailAddress_2.AddressID = but020.addrnumber

association[1..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                   and $projection.AddressID = _BPProtectedAddress.AddressID                                                                 

{  
  key but020.partner as BusinessPartner,
  key I_AddressEmailAddress_2.AddressID,
  key I_AddressEmailAddress_2.CommMediumSequenceNumber as OrdinalNumber,
  key I_AddressEmailAddress_2.AddressPersonID as Person,
  I_AddressEmailAddress_2.EmailAddressIsCurrentDefault as IsDefaultEmailAddress,
  I_AddressEmailAddress_2.EmailAddress, 
  cast('' as ad_flghome) as IsHomeEmailAddress,
  cast ( '' as ad_flnouse ) as CommNumberIsNotUsed,
  cast ( I_AddressEmailAddress_2.ValidityStartDate as ad_valfrom ) as ValidityStartDateTime,
  cast ( I_AddressEmailAddress_2.ValidityEndDate as ad_valto ) as ValidityEndDateTime, 

  _BusinessPartner,
  _BPProtectedAddress,
  I_AddressEmailAddress_2._AddressCommunicationRemark
 
}
where
  (I_AddressEmailAddress_2.AddressPersonID = ' ' or _BusinessPartner.BusinessPartnerCategory = '1') //Do not return Person Workplace Addresses

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSEMAILADDRESS_2",
"I_BUSINESSPARTNER",
"BUT020"
],
"ASSOCIATED":
[
"I_ADDRESSCOMMUNICATIONREMARK_2",
"I_BPPROTECTEDADDRESS",
"I_BUSINESSPARTNER"
],
"BASE":
[
"I_ADDRESSEMAILADDRESS_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/