I_BPCustomerCompanyProcessTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Business Partner Customer Company Code Process Data - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
define view entity I_BPCustomerCompanyProcessTP
  as select from I_BPCustomerCompanyProcess

  association        to parent I_BPCustomerProcessTP as _Customer                   on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject
                                                                                    and $projection.BPAssignmentID          = _Customer.BPAssignmentID
  composition [0..*] of I_BPCustomerDunningProcessTP as _CustomerDunning
  composition [0..*] of I_BPCustomerWhgdTaxProcessTP as _CustomerWithholdingTax

  association        to I_BusinessPartnerProcessTP   as _BusinessPartner            on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BPProcessKPIRecordType     as _RecordType                 on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                    and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                    and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                    and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH    as _KPIUpdateStatusText        on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus

  association [0..1] to I_AccountingClerk            as _AccountingClerk            on  $projection.CompanyCode     = _AccountingClerk.CompanyCode
                                                                                    and $projection.AccountingClerk = _AccountingClerk.AccountingClerk
  association [0..1] to I_ToleranceGroup             as _ToleranceGroup             on  $projection.CompanyCode        = _ToleranceGroup.CompanyCode
                                                                                    and $projection.APARToleranceGroup = _ToleranceGroup.APARToleranceGroup
  association [0..1] to I_PaymentBlockingReason      as _PaymentBlockingReason      on  $projection.PaymentBlockingReason = _PaymentBlockingReason.PaymentBlockingReason
  association [0..1] to I_CashPlanningGroup          as _CashPlanningGroup          on  $projection.CashPlanningGroup = _CashPlanningGroup.CashPlanningGroup
  association [0..1] to I_GLAccountInCompanyCode     as _ReconciliationAccount      on  $projection.CompanyCode                          = _ReconciliationAccount.CompanyCode
                                                                                    and $projection.ReconciliationAccount                = _ReconciliationAccount.GLAccount
                                                                                    and _ReconciliationAccount.ReconciliationAccountType = 'D'
  association [0..1] to I_Customer                   as _HeadOffice                 on  $projection.CustomerHeadOffice = _HeadOffice.Customer
  association [0..1] to I_AcctgDocItmDspSqncRule     as _LayoutSortingRule          on  $projection.LayoutSortingRule = _LayoutSortingRule.AcctgDocItmDisplaySequenceRule

  association [0..1] to I_Paymentmethodsupplement    as _PaymentMethodSupplement    on  $projection.PaymentMethodSupplement = _PaymentMethodSupplement.PaymentMethodSupplement
  association [0..1] to I_CustomerCompany            as _AlternativePayer           on  $projection.AlternativePayerAccount = _AlternativePayer.Customer
                                                                                    and $projection.CompanyCode             = _AlternativePayer.CompanyCode
  association [0..1] to I_Housebank                  as _HouseBank                  on  $projection.HouseBank   = _HouseBank.HouseBank
                                                                                    and $projection.CompanyCode = _HouseBank.CompanyCode
  association [0..1] to I_InterestCalculationCode    as _InterestCalculationCode    on  $projection.InterestCalculationCode = _InterestCalculationCode.InterestCalculationCode
  association [0..1] to I_MM_SuplrReleaseGroupVH     as _SupplierReleaseGroup       on  $projection.SupplierReleaseGroup = _SupplierReleaseGroup.SupplierReleaseGroup
  association [0..1] to I_PaymentTerms               as _CreditMemoPaymentTerms     on  $projection.CreditMemoPaymentTerms = _CreditMemoPaymentTerms.PaymentTerms
  association [0..1] to I_CustomerPaymentTerms       as _BillExchChargePaymentTerms on  $projection.BillExchChargePaymentTerms = _BillExchChargePaymentTerms.CustomerPaymentTerms
  association [0..1] to I_NegotiatedLeave            as _NegotiatedLeave            on  $projection.KnownOrNegotiatedLeave = _NegotiatedLeave.KnownOrNegotiatedLeave
  association [0..1] to I_Customer                   as _BuyingGroupAccount         on  $projection.BuyingGroupAccountNumber = _BuyingGroupAccount.Customer
  association [0..1] to I_BPPeriodicAccountStatement as _PeriodicAccountStatement   on  $projection.BPPeriodicAccountStatement = _PeriodicAccountStatement.BPPeriodicAccountStatement
  association [0..1] to I_AcctsReceivablePledging    as _AcctsReceivablePledging    on  $projection.AcctsReceivablePledgingCode = _AcctsReceivablePledging.AcctsReceivablePledgingCode
                                                                                    and $projection.CompanyCode = _AcctsReceivablePledging.CompanyCode
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key BPAssignmentID,
  key CompanyCode,
      Customer,
      PersonnelNumber,
      PhysicalInventoryBlockInd,
      DeletionIndicator,
      LayoutSortingRule,
      AccountingClerk,
      ReconciliationAccount,
      AuthorizationGroup,
      CustomerHeadOffice,
      AlternativePayerAccount,
      PaymentMethodsList,
      CustomerSupplierClearingIsUsed,
      PaymentBlockingReason,
      PaymentTerms,
      BillExchChargePaymentTerms,
      InterestCalculationCode,
      InterestCalculationDate,
      IntrstCalcFrequencyInMonths,
      AccountByCustomer,
      UserAtCustomer,
      CustomerAccountNote,
      CashPlanningGroup,
      CollectiveInvoiceVariant,
      IsToBeLocallyProcessed,
      BPPeriodicAccountStatement,
      LastInterestCalcRunDate,
      RecordPaymentHistoryIndicator,
      APARToleranceGroup,
      CheckPaidDurationInDays,
      HouseBank,
      ItemIsToBePaidSeparately,
      CustPreviousMasterRecordNumber,
      KnownOrNegotiatedLeave,
      DunningNoticeGroup,
      LockboxInternalID,
      PaymentMethodSupplement,
      BuyingGroupAccountNumber,
      PaytAdviceIsSentbyEDI,
      SupplierReleaseGroup,
      AccountingClerkFaxNumber,
      AccountingClerkInternetAddress,
      CreditMemoPaymentTerms,
      ValueAdjustmentKey,
      DeletionIsBlocked,
      AccountingClerkPhoneNumber,
      AcctsReceivablePledgingCode,
      //      WithholdingTaxCountry,

      //      @Semantics.booleanIndicator

      //      IsBusinessPurposeCompleted,

      //      PaymentClearingGroup,

      PaymentReason,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcSrceLastChgdDateTime,
      cast(
        case
          when MDChgProcessSourceModified = '' then 'N'
          when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified
      ) as MDChgProcKPIUpdateStatus,

      _Customer,
      _CustomerDunning,
      _CustomerWithholdingTax,
      _BusinessPartner,
      _CompanyCode,
      _RecordType,
      _KPIUpdateStatusText,
      _AccountingClerk,
      _ToleranceGroup,
      _PaymentBlockingReason,
      _CashPlanningGroup,
      _ReconciliationAccount,
      _HeadOffice,
      _LayoutSortingRule,
      _PaymentMethodSupplement,
      _AlternativePayer,
      _HouseBank,
      _InterestCalculationCode,
      _SupplierReleaseGroup,
      _CreditMemoPaymentTerms,
      _BillExchChargePaymentTerms,
      _NegotiatedLeave,
      _BuyingGroupAccount,
      _PeriodicAccountStatement,
      _AcctsReceivablePledging
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCUSTOMERCOMPANYPROCESS"
],
"ASSOCIATED":
[
"I_ACCOUNTINGCLERK",
"I_ACCTGDOCITMDSPSQNCRULE",
"I_ACCTSRECEIVABLEPLEDGING",
"I_BPCUSTOMERDUNNINGPROCESSTP",
"I_BPCUSTOMERPROCESSTP",
"I_BPCUSTOMERWHGDTAXPROCESSTP",
"I_BPPERIODICACCOUNTSTATEMENT",
"I_BPPROCESSKPIRECORDTYPE",
"I_BUSINESSPARTNERPROCESSTP",
"I_CASHPLANNINGGROUP",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_CUSTOMERCOMPANY",
"I_CUSTOMERPAYMENTTERMS",
"I_GLACCOUNTINCOMPANYCODE",
"I_HOUSEBANK",
"I_INTERESTCALCULATIONCODE",
"I_MDCHANGEPROCESSKPIROWVH",
"I_MM_SUPLRRELEASEGROUPVH",
"I_NEGOTIATEDLEAVE",
"I_PAYMENTBLOCKINGREASON",
"I_PAYMENTMETHODSUPPLEMENT",
"I_PAYMENTTERMS",
"I_TOLERANCEGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/