I_BPCustDeptAddrDepdntInfo

@AbapCatalog.sqlViewName: 'IBPCUSTDEPTADDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'BP and Cust dept Addr Depdnt Info'
@ClientHandling.algorithm : #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #COMPOSITE

define view I_BPCustDeptAddrDepdntInfo
  as select distinct from   I_BusPartAddress               as BusinessPartnerAddress
    inner join              I_BusinessPartnerCustomer      as BusinessPartnerCustomer      on BusinessPartnerAddress.BusinessPartner = BusinessPartnerCustomer.BusinessPartner
    left outer to many join I_CustomerDepartment           as CustomerDepartment           on CustomerDepartment.Customer = BusinessPartnerCustomer.Customer
    left outer to many join I_CustDepartmentAddrDepdntInfo as CustDepartmentAddrDepdntInfo on  CustDepartmentAddrDepdntInfo.Customer  = BusinessPartnerCustomer.Customer
                                                                                           and CustDepartmentAddrDepdntInfo.AddressID = BusinessPartnerAddress.AddressID

  association [1..1] to I_BPCurrentDefaultAddress as _DefaultAddress  on _DefaultAddress.BusinessPartner = $projection.BusinessPartner

  association [1..1] to I_BusinessPartner         as _BusinessPartner on _BusinessPartner.BusinessPartner = $projection.BusinessPartner

  association [1..1] to I_Customer                as _Customer        on $projection.Customer = _Customer.Customer
  
  
{
       @ObjectModel.foreignKey.association: '_BusinessPartner'
  key  BusinessPartnerAddress.BusinessPartner as BusinessPartner,
  key  BusinessPartnerAddress.AddressID       as AddressID,
       @ObjectModel.foreignKey.association: '_Customer'
  key  BusinessPartnerCustomer.Customer       as Customer,
       // Common fields Both in WRF4 and WRF4_ADDR

       // Logic for all the common fields:

       //    If Address dependent data exists show data from WRF4_ADDR , Else shown nothing for non default address

       //   For default address show department data from WRF4 (if exists)

  key  case when CustDepartmentAddrDepdntInfo.AddressID is not initial then CustDepartmentAddrDepdntInfo.CustomerDepartment           // Address dependent data  - Show data from WRF4_addr

       else
         case when BusinessPartnerAddress.AddressID = _DefaultAddress.AddressID then  CustomerDepartment.CustomerDepartment      // Only for default address fetch address dependent departments from WRF4_addr

         else cast( ''  as abtnr )                                                                                                                     // Non default address with no department data

         end
       end                                    as CustomerDepartment,

       case when CustDepartmentAddrDepdntInfo.AddressID is not initial then CustDepartmentAddrDepdntInfo.ReceivingPoint           // Address dependent data  - Show data from WRF4_addr

         else
           case when BusinessPartnerAddress.AddressID = _DefaultAddress.AddressID then  CustomerDepartment.ReceivingPoint       // Only for default address fetch address dependent departments from WRF4_addr

           else cast( ''  as empst )                                                                                                                     // Non default address with no department data

           end
         end                                  as ReceivingPoint,


       case when CustDepartmentAddrDepdntInfo.AddressID is not initial then CustDepartmentAddrDepdntInfo.DepartmentLayout           // Address dependent data  - Show data from WRF4_addr

         else
           case when BusinessPartnerAddress.AddressID = _DefaultAddress.AddressID then  CustomerDepartment.DepartmentLayout       // Only for default address fetch address dependent departments from WRF4_addr

           else cast( ''  as layvar )                                                                                                                     // Non default address with no department data

           end
         end                                  as DepartmentLayout,

       case when CustDepartmentAddrDepdntInfo.AddressID is not initial then CustDepartmentAddrDepdntInfo.DepartmentLayoutAreaSchema          // Address dependent data  - Show data from WRF4_addr

        else
          case when BusinessPartnerAddress.AddressID = _DefaultAddress.AddressID then  CustomerDepartment.DepartmentLayoutAreaSchema       // Only for default address fetch address dependent departments from WRF4_addr

          else cast( ''  as flvar )                                                                                                                     // Non default address with no department data

          end
        end                                   as DepartmentLayoutAreaSchema,
        
        @Semantics.quantity.unitOfMeasure: 'RetailLocationSellingAreaUnit'

       case when CustDepartmentAddrDepdntInfo.AddressID is not initial then CustDepartmentAddrDepdntInfo.RetailLocationSellingAreaSize         // Address dependent data  - Show data from WRF4_addr

         else
           case when BusinessPartnerAddress.AddressID = _DefaultAddress.AddressID then  CustomerDepartment.RetailLocationSellingAreaSize       // Only for default address fetch address dependent departments from WRF4_addr

           else cast( 0  as verfl_wws )                                                                                                                     // Non default address with no department data

           end
         end                                  as RetailLocationSellingAreaSize,

       case when CustDepartmentAddrDepdntInfo.AddressID is not initial then CustDepartmentAddrDepdntInfo.RetailLocationSellingAreaUnit         // Address dependent data  - Show data from WRF4_addr

        else
          case when BusinessPartnerAddress.AddressID = _DefaultAddress.AddressID then  CustomerDepartment.RetailLocationSellingAreaUnit        // Only for default address fetch address dependent departments from WRF4_addr

          else cast( ''  as verfe_wws )                                                                                                                     // Non default address with no department data

          end
        end                                   as RetailLocationSellingAreaUnit,


       // KNA1 only fields

       BusinessPartnerCustomer.CustomerAccountGroup,
       BusinessPartnerCustomer.CustomerClassification,
       BusinessPartnerCustomer.AuthorizationGroup,
       BusinessPartnerCustomer.DeliveryIsBlocked,
       BusinessPartnerCustomer.PostingIsBlocked,
       BusinessPartnerCustomer.BillingIsBlockedForCustomer,
       BusinessPartnerCustomer.OrderIsBlockedForCustomer,
       BusinessPartnerCustomer.CustomerCorporateGroup,
       BusinessPartnerCustomer.Supplier,
       BusinessPartnerCustomer.IndustryCode1,
       BusinessPartnerCustomer.IndustryCode2,
       BusinessPartnerCustomer.IndustryCode3,
       BusinessPartnerCustomer.AlternativePayerAccount,
       BusinessPartnerCustomer.DataMediumExchangeIndicator,
       BusinessPartnerCustomer.VATLiability,
       BusinessPartnerCustomer.FiscalAddress,
       @Semantics.booleanIndicator:true
       BusinessPartnerCustomer.IsNaturalPerson,
       BusinessPartnerCustomer.CityLocationCoordinatesCode,
       BusinessPartnerCustomer.DeliveryDateTypeRule,
       BusinessPartnerCustomer.Plant,
       BusinessPartnerCustomer.DataExchangeInstructionKey,
       BusinessPartnerCustomer.IsCompetitor,
       BusinessPartnerCustomer.IsSalesPartner,
       BusinessPartnerCustomer.IsDefaultSoldToParty,
       BusinessPartnerCustomer.IsConsumer,
       BusinessPartnerCustomer.FreeDefinedAttribute03,
       BusinessPartnerCustomer.CustomerConditionGroup1,
       BusinessPartnerCustomer.CustomerConditionGroup2,
       BusinessPartnerCustomer.CustomerConditionGroup3,
       BusinessPartnerCustomer.CustomerConditionGroup4,
       BusinessPartnerCustomer.CustomerConditionGroup5,
       _BusinessPartner,
       _Customer
       

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNERCUSTOMER",
"I_BUSPARTADDRESS",
"I_CUSTDEPARTMENTADDRDEPDNTINFO",
"I_CUSTOMERDEPARTMENT"
],
"ASSOCIATED":
[
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER",
"I_CUSTOMER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/