I_BPCntctPersnEmailAddrProcTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BP Workplace Email Addr Process Data - TP'
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
define view entity I_BPCntctPersnEmailAddrProcTP
  as select from I_BPCntctPersnEmailAddressProc
  association [1..1] to I_BusPartRelationshipProcessTP        as _BPRelProcess        on  $projection.MasterDataChangeProcess = _BPRelProcess.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep        = _BPRelProcess.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem  = _BPRelProcess.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject  = _BPRelProcess.MDChgProcessSrceObject
  association        to parent I_BPContactPersonAddressProcTP as _WorkplaceAddress    on  $projection.MasterDataChangeProcess = _WorkplaceAddress.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep        = _WorkplaceAddress.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem  = _WorkplaceAddress.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject  = _WorkplaceAddress.MDChgProcessSrceObject
                                                                                      and $projection.AddressNumber           = _WorkplaceAddress.AddressNumber
  association [0..1] to I_BPRelshpProcessKPIRecordType        as _RecordType          on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH             as _KPIUpdateStatusText on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages             as _RecordMessages      on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      AddrCommunicationValidFromDate,
      IsDefaultEmailAddress,
      IsHomeEmailAddress,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      EmailAddress,
      /* Record Identification */
      case
        when _WorkplaceAddress.BusinessPartnerFullName <> ''
          then
            case
              when _WorkplaceAddress.AddressNumber <> ''
                then
                concat_with_space(_WorkplaceAddress.BusinessPartnerFullName,
                  concat_with_space(
                    concat_with_space(
                      concat_with_space(
                        concat_with_space(_WorkplaceAddress.StreetName,_WorkplaceAddress.HouseNumber,1)
                      ,_WorkplaceAddress.PostalCode,1)
                    ,_WorkplaceAddress.CityName,1)
                  ,_WorkplaceAddress.Country,1),1)
              else _WorkplaceAddress.BusinessPartnerName
            end
        else ''
      end                                                            as AddressLine1Text,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,
      /* Associations */
      _BPRelProcess,
      _WorkplaceAddress,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCNTCTPERSNEMAILADDRESSPROC",
"I_BPCONTACTPERSONADDRESSPROCTP"
],
"ASSOCIATED":
[
"I_BPCONTACTPERSONADDRESSPROCTP",
"I_BPRELSHPPROCESSKPIRECORDTYPE",
"I_BUSPARTRELATIONSHIPPROCESSTP",
"I_MDCHANGEPROCESSKPIROWVH",
"I_MDCHGPROCRECORDMESSAGES"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/