I_BOMExplosionDate

@AbapCatalog.sqlViewName: 'IPPBOMEXPLDATE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'BOMExplosionDateID'
@ObjectModel.semanticKey: ['BOMExplosionDateID']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #MASTER}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'BOM Explosion Date'

define view I_BOMExplosionDate
  as select from snum as s
  association [1..1] to I_Material as _Material on $projection.Material = _Material.Material
  association [1..1] to I_Product  as _Product  on $projection.Material = _Product.Product
  association [1..1] to I_Plant    as _Plant    on $projection.Plant = _Plant.Plant
{
      // Key

      @ObjectModel.text.element: ['BOMExplosionDateText']
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key cast(s.sernr as pph_sernr preserving type) as BOMExplosionDateID,

      // Other data

      @Semantics.businessDate.at: true
      s.brutr                                    as BOMExplosionFixedKeyDate,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductStdVH', element: 'Product' } } ]
      @ObjectModel.foreignKey.association: '_Product'
      s.matnr                                    as Material,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_Plant'
      s.werks                                    as Plant,
      @Semantics.text: true
      cast(s.sntxt as pph_sntxt preserving type) as BOMExplosionDateText,
      s.xloek                                    as IsDeleted,
      s.techs                                    as EffectivityParameterVariant,

      // Associations

      _Material,
      _Product,
      _Plant
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SNUM"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_PLANT",
"I_PRODUCT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/