I_AstAcqnAndRtrmtOverview

@AbapCatalog.sqlViewName: 'IASTACQRETOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Asset Acquisitions and Retirements Overview'
@ObjectModel.usageType: {
  sizeCategory: #XXL,
  serviceQuality: #C,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view I_AstAcqnAndRtrmtOverview
  with parameters
    P_KeyDate                     : fagl_keydate,
    P_AssetAccountingKeyFigureSet : faa_key_figure_set
  as select from I_FixedAssetTransaction(P_KeyDate                    : :P_KeyDate,
                                         P_AssetAccountingKeyFigureSet: :P_AssetAccountingKeyFigureSet)
  association [0..1] to I_FixedAssetForLedger as _FixedAssetForLedger on  _FixedAssetForLedger.CompanyCode      = $projection.CompanyCode
                                                                      and _FixedAssetForLedger.MasterFixedAsset = $projection.MasterFixedAsset
                                                                      and _FixedAssetForLedger.FixedAsset       = $projection.FixedAsset
                                                                      and _FixedAssetForLedger.Ledger           = $projection.Ledger
  association [1]    to I_AssetRedesignSwitchStatus as _AssetRedesignSwitchStatus on  _AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = '' 
                                                                                  or  _AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = 'X'
{
  key    CompanyCode,
  key    AssetDepreciationArea,
  key    MasterFixedAsset,
  key    FixedAsset,
  key    Ledger,
  key    LedgerFiscalYear,
  key    FiscalYear,
  key    FiscalPeriod,
  key    SubLedgerAcctLineItemType,
  key    AssetAcctTransClassfctn,
  key    AssetAccountingKeyFigure,
  key    AssetAccountingKeyFigureSet,
  key    AccountingDocument,
  key    TransactionSubitem,
  key    DebitCreditCode,
  key    CurrencyRole,

         PostingDate,

         /* Fields from Fixed Asset */
         AssetClass,
         AssetAccountDetermination,
         _FixedAssetForLedger.AssetCapitalizationDate,
         _FixedAssetForLedger.AssetDeactivationDate,
         cast(_FixedAsset.AssetCountryOfOrigin as faa_asset_cntry_of_origin) as AssetCountryOfOrigin,
         _FixedAsset.Supplier                                                as AssetSupplier,
         _FixedAsset._Supplier.SupplierAccountGroup,
         _FixedAsset._Supplier.AuthorizationGroup                            as SupplierBasicAuthorizationGrp,

         /* Fields from Fixed Asset (Time-Dependent Data) */
         AssetCostCenter,
         AssetPlant,
         AssetProfitCenter,
         AssetSegment,

         /* Text Fields */
         CompanyCodeName,
         FixedAssetDescription,

         @Environment.sql.passValue: true
         SelectedCurrencyBranch,

         /* Amounts */
         @Semantics.currencyCode:true
         DisplayCurrency,

         @Semantics.amount.currencyCode: 'DisplayCurrency'
         AcqnProdnAmtInDspCrcy,
         @Semantics.amount.currencyCode: 'DisplayCurrency'
         RtrmtNetBookValueAmtInDspCrcy,

         /* Associations */
         _FixedAsset,
         _AssetClassText,
         @Consumption.hidden: true  
         _AssetRedesignSwitchStatus //for DCL

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FIXEDASSET",
"I_FIXEDASSETFORLEDGER",
"I_FIXEDASSETTRANSACTION",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_ASSETCLASSTEXT",
"I_ASSETREDESIGNSWITCHSTATUS",
"I_FIXEDASSET",
"I_FIXEDASSETFORLEDGER"
],
"BASE":
[
"I_FIXEDASSETTRANSACTION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/