I_AsstmtMdlUsrToAsstmtMdl_2

@AbapCatalog.sqlViewName: 'IASMUSERTOMOD2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Assortment User Assignment to Assortment Module'
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM: {
  viewType: #BASIC,

  lifecycle: {
    contract: {
      type: #NONE
    }
  }
}
@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #M,
        dataClass: #MASTER
   }
}

define view I_AsstmtMdlUsrToAsstmtMdl_2
  as select from rfm_asm_site as site_assignment
    inner join   t001w        as site on  site.kunnr   = site_assignment.site
                                      and (
                                         site.vlfkz    = 'A'
                                         or site.vlfkz = 'B'
                                       )
                                      and site.achvm   = ''
    inner join   wrf1                 on wrf1.locnr = site.kunnr
  association [0..1] to I_Site as _Site on _Site.SiteCustomer   = site_assignment.site
                                        and(
                                          _Site.SiteCategory    = 'A'
                                          or _Site.SiteCategory = 'B'
                                        )

{
  key object_guid                                                                       as AssortmentModuleObjectUUID,
  key site                                                                              as AssortmentModuleUser,
  key valid_from                                                                        as ValidityStartDate,
      valid_to                                                                          as ValidityEndDate,
      site.vkorg                                                                        as SalesOrganization,
      site.vtweg                                                                        as DistributionChannel,
      last_changed_by                                                                   as LastChangedByUserName,
      last_changed_at                                                                   as LastChangeDateTime,
      tstmp_to_dats( last_changed_at, $session.user_timezone, $session.client, 'NULL' ) as LastChangeDate,

      _Site
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"RFM_ASM_SITE",
"T001W",
"WRF1"
],
"ASSOCIATED":
[
"I_SITE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/