I_AssldReltdSerialNumberBatch

@AbapCatalog.sqlViewName: 'IMPEASSRLTDSRNB'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Assembled Related Serial Number and/or Batch'
define view I_AssldReltdSerialNumberBatch
  as select from           P_AssldReltdSerialNumberBatch as AssldReltdSerialNumberBatch
    left outer to one join I_OrderComponent              as OrderComponent on  OrderComponent.Reservation     = AssldReltdSerialNumberBatch.Reservation
                                                                           and OrderComponent.ReservationItem = AssldReltdSerialNumberBatch.ReservationItem
                                                                           and OrderComponent.RecordType      = AssldReltdSerialNumberBatch.RecordType

{
  key AssldReltdSerialNumberBatch.Reservation,
  key AssldReltdSerialNumberBatch.ReservationItem,
  key AssldReltdSerialNumberBatch.RecordType,
  key AssldReltdSerialNumberBatch.OpActyNtwkInstance,
  key AssldReltdSerialNumberBatch.OpActyNtwkElement,
  key AssldReltdSerialNumberBatch.AssemblyShopFloorItem,
  key AssldReltdSerialNumberBatch.ShopFloorItem,
  key AssldReltdSerialNumberBatch.Batch,
      @ObjectModel.text.element: 'MaterialName'
  key AssldReltdSerialNumberBatch.Material,
  key AssldReltdSerialNumberBatch.Plant,
      AssldReltdSerialNumberBatch._ShopFloorItem.SerialNumber,
      AssldReltdSerialNumberBatch._ShopFloorItem._Equipment.ManufacturerSerialNumber,
      AssldReltdSerialNumberBatch._BatchDistinct.BatchBySupplier,
      @Semantics.text: true
      AssldReltdSerialNumberBatch._Material._Text[1: Language=$session.system_language].MaterialName,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      AssldReltdSerialNumberBatch.MaterialComponentQuantity,
      @Semantics.unitOfMeasure: true
      AssldReltdSerialNumberBatch.MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(case OrderComponent.MaterialCompIsVariableSized
          when 'X' then AssldReltdSerialNumberBatch.QuantityInEntryUnit
          else AssldReltdSerialNumberBatch.MaterialComponentQuantity
      end as erfmgv preserving type) as QuantityInEntryUnit,
      @Semantics.unitOfMeasure: true
      cast(case OrderComponent.MaterialCompIsVariableSized
          when 'X' then AssldReltdSerialNumberBatch.EntryUnit
          else AssldReltdSerialNumberBatch.MaterialBaseUnit
      end as erfme preserving type)  as EntryUnit,

      AssldReltdSerialNumberBatch._OpActyNtwkInstance,
      AssldReltdSerialNumberBatch._OperationActivityInstance,
      AssldReltdSerialNumberBatch._ReservationHeader,
      AssldReltdSerialNumberBatch._ShopFloorItem,
      AssldReltdSerialNumberBatch._ParentShopFloorItem,
      AssldReltdSerialNumberBatch._Material,
      AssldReltdSerialNumberBatch._Plant
}
where
  AssldReltdSerialNumberBatch.MaterialComponentQuantity <> 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHDISTINCT",
"I_EQUIPMENT",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_ORDERCOMPONENT",
"I_SHOPFLOORITEM",
"P_ASSLDRELTDSERIALNUMBERBATCH"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_PLANT",
"I_RESERVATIONDOCUMENTHEADER",
"I_SHOPFLOORITEM"
],
"BASE":
[
"P_ASSLDRELTDSERIALNUMBERBATCH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/