I_AssetValuationForLedger

@AbapCatalog: {sqlViewName: 'IFIASTVALFORLDGR', preserveKey: true, compiler.compareFilter: true}
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fixed Asset Valuation for Ledger'
@VDM.viewType: #COMPOSITE
@ObjectModel: { usageType.serviceQuality: #C,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MASTER,
                modelingPattern: #NONE,
                supportedCapabilities: [ #SQL_DATA_SOURCE,
                                         #CDS_MODELING_DATA_SOURCE ]
              }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view I_AssetValuationForLedger
  as select from P_AssetValuationForLedger

  association [1..1] to I_CompanyCode               as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_MasterFixedAsset          as _MasterFixedAsset          on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                  and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
  association [1..1] to I_FixedAsset                as _FixedAsset                on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                  and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                                  and $projection.FixedAsset       = _FixedAsset.FixedAsset
  association [1..1] to I_Ledger                    as _Ledger                    on  $projection.Ledger = _Ledger.Ledger
  association [0..1] to I_DepreciationAreaForLedger as _DepreciationArea          on  $projection.CompanyCode               = _DepreciationArea.CompanyCode
                                                                                  and $projection.Ledger                    = _DepreciationArea.Ledger
                                                                                  and $projection.AssetRealDepreciationArea = _DepreciationArea.AssetDepreciationArea
  association [0..1] to I_ReplacementValueIndexSers as _ReplacementValueIndexSers on  $projection.ReplacementValueIndexSers = _ReplacementValueIndexSers.ReplacementValueIndexSers
  association [0..1] to I_Currency                  as _CompanyCodeCurrency       on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_FixedAssetUsageObject     as _FixedAssetUsageObject     on  $projection.CompanyCode           = _FixedAssetUsageObject.CompanyCode
                                                                                  and $projection.FixedAssetUsageObject = _FixedAssetUsageObject.FixedAssetUsageObject
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAsset'
  key FixedAsset,
      @ObjectModel.foreignKey.association: '_Ledger'
  key Ledger,
      @ObjectModel.foreignKey.association: '_DepreciationArea'
  key AssetRealDepreciationArea,
  key ValidityEndDate,

      ValidityStartDate,
      DepreciationStartDate,
      SpecialDeprStartDate,
      DeprKeyChangeoverYear,
      DeprKeyChangeoverPeriod,
      DepreciationKey,
      InvestmentSupportMeasure, //Not supported with active BF

      PlannedUsefulLifeInPeriods,
      PlannedUsefulLifeInYears,
      cast(VintageYear as fis_vyear)                as VintageYear, //Not supported with active BF

      VintageMonth, //Not supported with active BF

      cast (OriglAstUsefulLifeInPerds as fis_ndurp) as OriglAstUsefulLifeInPerds, //Not supported with active BF

      OriglAstUsefulLifeInYears, //Not supported with active BF

      @ObjectModel.foreignKey.association: '_ReplacementValueIndexSers'
      ReplacementValueIndexSers,
      RplcmtValueAgingIndexSers,
      AcqnProdnCostScrapPercent,
      VariableDeprPercent,
      LastRetirementValueDate,
      DepreciationAreaType,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      ScrapAmountInCoCodeCrcy,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode: true
      _CompanyCode.Currency                         as CompanyCodeCurrency,
      AssetOpgReadinessDate,
      FixedAssetUsageObject,

      /* Associations */
      _CompanyCode,
      _MasterFixedAsset,
      _FixedAsset,
      _Ledger,
      _DepreciationArea,
      _ReplacementValueIndexSers,
      _CompanyCodeCurrency,
      _FixedAssetUsageObject
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"P_ASSETVALUATIONFORLEDGER"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_DEPRECIATIONAREAFORLEDGER",
"I_FIXEDASSET",
"I_FIXEDASSETUSAGEOBJECT",
"I_LEDGER",
"I_MASTERFIXEDASSET",
"I_REPLACEMENTVALUEINDEXSERS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/