I_AssetKeyFigureHierarchyNode

@AbapCatalog: {sqlViewName: 'IFASSETKFHIERN', preserveKey: true}
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Fixed Asset Key Figure Hierarchy Node'
@VDM.viewType: #BASIC
@ObjectModel: { dataCategory: #HIERARCHY,
                usageType.serviceQuality: #B,
                usageType.sizeCategory: #L,
                usageType.dataClass: #CUSTOMIZING }
@hierarchy.parentChild:
{ recurse:          {   parent: 'ParentNode',   child:  'HierarchyNode' },
  siblingsOrder:    {   by: 'AssetAccountingSortedKeyFigure',    direction: 'ASC'   },
  directory:        '_Hierarchy'
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view I_AssetKeyFigureHierarchyNode
  as select from    P_TF_AssetKeyFigHierarchyNode( P_SAPClient : $session.client )
    left outer join I_AssetSortedKeyFigureSetSpec on  P_TF_AssetKeyFigHierarchyNode.AssetAccountingKeyFigureSet = I_AssetSortedKeyFigureSetSpec.AssetAccountingKeyFigureSet
                                                  and P_TF_AssetKeyFigHierarchyNode.AssetAccountingKeyFigure    = I_AssetSortedKeyFigureSetSpec.AssetAccountingKeyFigure
                                                  and P_TF_AssetKeyFigHierarchyNode.NodeType                    = 'L'

  association [0..1] to I_AssetSortedKeyFigureSetSpec  as _AssetKeyFigureSetSpec on  $projection.AssetAccountingKeyFigureSet    = _AssetKeyFigureSetSpec.AssetAccountingKeyFigureSet
                                                                                 and $projection.AssetAccountingSortedKeyFigure = _AssetKeyFigureSetSpec.AssetAccountingSortedKeyFigure
  association [1..1] to I_AssetKeyFigureSet            as _AssetKeyFigureSet     on  $projection.AssetAccountingKeyFigureSet = _AssetKeyFigureSet.AssetAccountingKeyFigureSet
  association [1..1] to I_AssetKeyFigureHierarchy      as _Hierarchy             on  $projection.AssetAccountingKeyFigureSet  = _Hierarchy.AssetAccountingKeyFigureSet
                                                                                 and $projection.AssetAcctgKeyFigureHierarchy = _Hierarchy.AssetAcctgKeyFigureHierarchy
                                                                                 and $projection.ValidityEndDate              = _Hierarchy.ValidityEndDate
  association [0..*] to I_AssetKeyFigHierarchyNodeText as _Text                  on  $projection.AssetAccountingKeyFigureSet    = _Text.AssetAccountingKeyFigureSet
                                                                                 and $projection.AssetAcctgKeyFigureHierarchy   = _Text.AssetAcctgKeyFigureHierarchy
                                                                                 and $projection.HierarchyNode                  = _Text.HierarchyNode
                                                                                 and $projection.AssetAccountingSortedKeyFigure = ''
{
        @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
        @ObjectModel.foreignKey.association: '_AssetKeyFigureSet'
  key   P_TF_AssetKeyFigHierarchyNode.AssetAccountingKeyFigureSet,
        @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
        @ObjectModel.foreignKey.association: '_Hierarchy'
  key   AssetAcctgKeyFigureHierarchy,
        @ObjectModel.text.association: '_Text'
  key   HierarchyNode,
        @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
        @Semantics.businessDate.to: true
  key   ValidityEndDate,


        ParentNode,
        @Semantics.businessDate.from: true
        ValidityStartDate,

        @ObjectModel.foreignKey.association: '_AssetKeyFigureSetSpec'
        case NodeType
          when 'L' then AssetAccountingSortedKeyFigure
          else ''
        end as AssetAccountingSortedKeyFigure,

        _AssetKeyFigureSetSpec,
        _AssetKeyFigureSet,
        _Hierarchy,
        _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSETSORTEDKEYFIGURESETSPEC"
],
"ASSOCIATED":
[
"I_ASSETKEYFIGHIERARCHYNODETEXT",
"I_ASSETKEYFIGUREHIERARCHY",
"I_ASSETKEYFIGURESET",
"I_ASSETSORTEDKEYFIGURESETSPEC"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/